Aroon_Oscillator_HeatMap

ÿþ//+------------------------------------------------------------------+

//|                                     Aroon_Oscillator_HeatMap.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "Aroon oscillator Heatmap indicator"

#property description "Aroon Horn: https://www.mql5.com/ru/code/22182"

#property description "Aroon Filter: https://www.mql5.com/ru/code/22183"

#property indicator_separate_window

#property indicator_buffers 4

#property indicator_plots   3

//--- plot UP

#property indicator_label1  "Up"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrForestGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot DN

#property indicator_label2  "Down"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrOrangeRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot NL

#property indicator_label3  "Neutral"

#property indicator_type3   DRAW_ARROW

#property indicator_color3  clrLightGray

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- input parameters

input uint     InpPeriod   =  10;      // Aroon Period

input double   InpFilter   =  50.0;    // Aroon Filter

#define        COUNT       (3)

//--- indicator buffers

double         BufferUP[];

double         BufferDN[];

double         BufferNL[];

//--- Aroon

double         BufferAroon[];

//--- global variables

string         prefix;

int            wnd;

//--- Aroon

double         filter;

int            period;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- set global variables

   prefix=MQLInfoString(MQL_PROGRAM_NAME)+"_";

   wnd=ChartWindowFind();

   SizeByScale();

   Descriptions();

//--- Aroon

   period=int(InpPeriod<1 ? 1 : InpPeriod);

   filter=(InpFilter<0 ? 0 : InpFilter);

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferUP,INDICATOR_DATA);

   SetIndexBuffer(1,BufferDN,INDICATOR_DATA);

   SetIndexBuffer(2,BufferNL,INDICATOR_DATA);

   SetIndexBuffer(3,BufferAroon,INDICATOR_CALCULATIONS);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   for(int i=0; i<COUNT; i++)

      PlotIndexSetInteger(i,PLOT_ARROW,167);

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferUP,true);

   ArraySetAsSeries(BufferDN,true);

   ArraySetAsSeries(BufferNL,true);

   ArraySetAsSeries(BufferAroon,true);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"Aroon oscillator Heatmap");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

   IndicatorSetInteger(INDICATOR_HEIGHT,60);

   IndicatorSetDouble(INDICATOR_MINIMUM,0);

   IndicatorSetDouble(INDICATOR_MAXIMUM,1);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<fmax(period,4)) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-1;

      ArrayInitialize(BufferUP,EMPTY_VALUE);

      ArrayInitialize(BufferDN,EMPTY_VALUE);

      ArrayInitialize(BufferNL,EMPTY_VALUE);

      ArrayInitialize(BufferAroon,0);

     }



//---  0AGQB Aroon

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      int bh=iHighest(NULL,PERIOD_CURRENT,MODE_HIGH,period,i);

      int bl=iLowest(NULL,PERIOD_CURRENT,MODE_LOW,period,i);

      if(bh==WRONG_VALUE || bl==WRONG_VALUE)

         continue;

      BufferAroon[i]=100.0*(bl-bh)/period;

     }

     

//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      SetNL(i);



      if(BufferAroon[i]>filter)

         SetUP(i);

      else if(BufferAroon[i]<-filter)

         SetDN(i);

      else

         SetNL(i);

     }

   

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| ChartEvent function                                              |

//+------------------------------------------------------------------+

void OnChartEvent(const int id,

                  const long &lparam,

                  const double &dparam,

                  const string &sparam)

  {

   if(id==CHARTEVENT_CHART_CHANGE)

     {

      for(int i=0;i<COUNT;i++)

         PlotIndexSetInteger(i,PLOT_LINE_WIDTH,SizeByScale());

      Descriptions();

      ChartRedraw();

     }

  }

//+------------------------------------------------------------------+

//| >72@0I05B @07<5@, A>>B25BAB2CNI89 <0AHB01C                      |

//+------------------------------------------------------------------+

uchar SizeByScale(void)

  {

   uchar scale=(uchar)ChartGetInteger(0,CHART_SCALE);

   uchar size=(scale<3 ? 1 : scale==3 ? 2 : scale==4 ? 5 : 8);

   return size;

  }

//+------------------------------------------------------------------+

//| ?8A0=85                                                         |

//+------------------------------------------------------------------+

void Descriptions(void)

  {

   int x=4;

   int y=1;

   int arr_colors[]={indicator_color1,indicator_color2,indicator_color3};

   string arr_texts[]={"Up direction","Down direction","Neutral"};

   string arr_names[COUNT];

   for(int i=0; i<COUNT; i++)

     {

      arr_names[i]=prefix+"label"+(string)i;

      arr_colors[i]=PlotIndexGetInteger(i,PLOT_LINE_COLOR);

      x=(i==0 ? x : i==1 ? 110 : 230);

      Label(arr_names[i],x,y,CharToString(167),16,arr_colors[i],"Wingdings");

      Label(arr_names[i]+"_txt",x+10,y+5,arr_texts[i],10,clrGray,"Calibri");

     }

  }

//+------------------------------------------------------------------+

//| K2>48B B5:AB>2CN <5B:C                                          |

//+------------------------------------------------------------------+

void Label(const string name,const int x,const int y,const string text,const int size,const color clr,const string font)

  {

   if(ObjectFind(0,name)!=wnd)

     {

      ObjectCreate(0,name,OBJ_LABEL,wnd,0,0,0,0);

      ObjectSetInteger(0,name,OBJPROP_SELECTABLE,false);

      ObjectSetInteger(0,name,OBJPROP_HIDDEN,true);

     }

   ObjectSetInteger(0,name,OBJPROP_XDISTANCE,x);

   ObjectSetInteger(0,name,OBJPROP_YDISTANCE,y);

   ObjectSetInteger(0,name,OBJPROP_CORNER,CORNER_LEFT_LOWER);

   ObjectSetInteger(0,name,OBJPROP_ANCHOR,ANCHOR_LEFT_LOWER);

   ObjectSetInteger(0,name,OBJPROP_FONTSIZE,size);

   ObjectSetInteger(0,name,OBJPROP_COLOR,clr);

//---

   ObjectSetString(0,name,OBJPROP_FONT,font);

   ObjectSetString(0,name,OBJPROP_TEXT,text);

   ObjectSetString(0,name,OBJPROP_TOOLTIP,"\n");

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

void SetUP(const int shift)

  {

   BufferUP[shift]=0.5;

   BufferDN[shift]=BufferNL[shift]=EMPTY_VALUE;

  }  

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

void SetDN(const int shift)

  {

   BufferDN[shift]=0.5;

   BufferUP[shift]=BufferNL[shift]=EMPTY_VALUE;

  }  

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

void SetNL(const int shift)

  {

   BufferNL[shift]=0.5;

   BufferUP[shift]=BufferDN[shift]=EMPTY_VALUE;

  }

//+------------------------------------------------------------------+