Color_PEMA_Digit

ÿþ//+------===------------------------------------------------------------+ 

//|                                                Color_PEMA_Digit.mq5 | 

//|                                         Copyright © 2010, Bruno Pio |

//|                                                                     | 

//+---------------------------------------------------------------------+ 

//| ;O @01>BK  8=48:0B>@0  A;54C5B  ?>;>68BL D09; SmoothAlgorithms.mqh |

//| 2 ?0?:C (48@5:B>@8N): :0B0;>3_40==KE_B5@<8=0;0\\MQL5\Include        |

//+---------------------------------------------------------------------+

#property copyright "Copyright © 2010, Bruno Pio"

#property link "" 

#property description "Pentuple Exponential Moving Average"

//---- =><5@ 25@A88 8=48:0B>@0

#property version   "1.00"

//---- >B@8A>2:0 8=48:0B>@0 2 >A=>2=>< >:=5

#property indicator_chart_window

//---- :>;8G5AB2> 8=48:0B>@=KE 1CD5@>2

#property indicator_buffers 2 

//---- 8A?>;L7>20=> 2A53> >4=> 3@0D8G5A:>5 ?>AB@>5=85

#property indicator_plots   1

//+----------------------------------------------+

//|  0@0<5B@K >B@8A>2:8 8=48:0B>@0              |

//+----------------------------------------------+

#property indicator_type1   DRAW_COLOR_LINE

//---- 2 :0G5AB25 F25B>2 ;8=88 8A?>;L7>20=K

#property indicator_color1  clrDeepPink,clrTeal

//---- ;8=8O 8=48:0B>@0 - =5?@5@K2=0O :@820O

#property indicator_style1  STYLE_SOLID

//---- B>;I8=0 ;8=88 8=48:0B>@0 @02=0 3

#property indicator_width1  3

//---- >B>1@065=85 <5B:8 8=48:0B>@0

#property indicator_label1  "Color_PEMA_Digit"

//+----------------------------------------------+

//|  ?8A0=85 :;0AA0 CMoving_Average             |

//+----------------------------------------------+

#include <SmoothAlgorithms.mqh> 

//+----------------------------------------------+

//---- >1JO2;5=85 ?5@5<5==KE :;0AA0 CMoving_Average 87 D09;0 SmoothAlgorithms.mqh

CMoving_Average EMA[8];

//+----------------------------------------------+

//|  >1JO2;5=85 ?5@5G8A;5=89                     |

//+----------------------------------------------+

enum Applied_price_ //"8? :>=AB0=BK

  {

   PRICE_CLOSE_ = 1,     //Close

   PRICE_OPEN_,          //Open

   PRICE_HIGH_,          //High

   PRICE_LOW_,           //Low

   PRICE_MEDIAN_,        //Median Price (HL/2)

   PRICE_TYPICAL_,       //Typical Price (HLC/3)

   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)

   PRICE_SIMPL_,         //Simpl Price (OC/2)

   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 

   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 

   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price 

   PRICE_DEMARK_         //Demark Price

  };

//+----------------------------------------------+

//|  %+  " + "                 |

//+----------------------------------------------+

input string  SirName="Color_PEMA_Digit"; // 5@20O G0ABL 8<5=8 3@0D8G5A:8E >1J5:B>2

input double EmaLength=50.01;             // 3;C18=0 A3;06820=8O                   

input Applied_price_ IPC=PRICE_CLOSE_;    // F5=>20O :>=AB0=B0

input int Shift=0;                        // A4283 8=48:0B>@0 ?> 3>@87>=B0;8 2 10@0E

input int PriceShift=0;                   // c4283 8=48:0B>@0 ?> 25@B8:0;8 2 ?C=:B0E

input uint Digit=2;                       // :>;8G5AB2> @07@O4>2 >:@C3;5=8O

input bool ShowPrice=true;                // ?>:07K20BL F5=>2CN <5B:C

//---- F25B0 F5=>2KE <5B>:

input color  Price_color=clrGray;         // F25B F5=>2>9 <5B:8

//+----------------------------------------------+

//---- >1JO2;5=85 48=0<8G5A:8E <0AA82>2, :>B>@K5 1C4CB 2 40;L=59H5< 8A?>;L7>20=K 2 :0G5AB25 8=48:0B>@=KE 1CD5@>2

double ExtLineBuffer[],ColorExtLineBuffer[];

double dPriceShift,PointPow10;

//---- 1JO2;5=85 AB@8=3>2 4;O B5:AB>2KE <5B>:

string Price_name;

//---- 1JO2;5=85 3;>10;L=KE ?5@5<5==KE

int min_rates_total;

//+------------------------------------------------------------------+    

//| PEMA indicator initialization function                           | 

//+------------------------------------------------------------------+  

void OnInit()

  {

//---- =8F80;870F8O ?5@5<5==KE =0G0;0 >BAGQB0 40==KE

   min_rates_total=9;

   PointPow10=_Point*MathPow(10,Digit);

//---- =8F80;870F8O AB@8=3>2

   Price_name=SirName+"Price";

//---- ?@52@0I5=85 48=0<8G5A:>3> <0AA820 ExtLineBuffer 2 8=48:0B>@=K9 1CD5@

   SetIndexBuffer(0,ExtLineBuffer,INDICATOR_DATA);

//---- ?@52@0I5=85 48=0<8G5A:>3> <0AA820 2 F25B>2>9, 8=45:A=K9 1CD5@   

   SetIndexBuffer(1,ColorExtLineBuffer,INDICATOR_COLOR_INDEX);

//---- 8=45:A0F8O M;5<5=B>2 2 1CD5@5 =5 :0: 2 B09<A5@88!

   ArraySetAsSeries(ExtLineBuffer,false);

   ArraySetAsSeries(ColorExtLineBuffer,false);

//---- >ACI5AB2;5=85 A42830 =0G0;0 >BAGQB0 >B@8A>2:8 8=48:0B>@0

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);

//--- 70?@5B =0 >B@8A>2:C 8=48:0B>@>< ?CABKE 7=0G5=89

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);

//---- 8=8F80;870F88 ?5@5<5==>9 4;O :>@>B:>3> 8<5=8 8=48:0B>@0

   string shortname;

   StringConcatenate(shortname,"Color_PEMA_Digit( Length = ",EmaLength,")");

//--- A>740=85 8<5=8 4;O >B>1@065=8O 2 >B45;L=>< ?>4>:=5 8 2> 2A?;K20NI59 ?>4A:07:5

   IndicatorSetString(INDICATOR_SHORTNAME,shortname);

//--- >?@545;5=85 B>G=>AB8 >B>1@065=8O 7=0G5=89 8=48:0B>@0

   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+1);

//---- =8F80;870F8O A42830 ?> 25@B8:0;8

   dPriceShift=_Point*PriceShift;

//---- 7025@H5=85 8=8F80;870F88

  }

//+------------------------------------------------------------------+

//| Custom indicator deinitialization function                       |

//+------------------------------------------------------------------+    

void OnDeinit(const int reason)

  {

//----

   ObjectDelete(0,Price_name);

//----

   ChartRedraw(0);

  }

//+------------------------------------------------------------------+  

//| PEMA iteration function                                          | 

//+------------------------------------------------------------------+  

int OnCalculate(

                const int rates_total,    // :>;8G5AB2> 8AB>@88 2 10@0E =0 B5:CI5< B8:5

                const int prev_calculated,// :>;8G5AB2> 8AB>@88 2 10@0E =0 ?@54K4CI5< B8:5

                const datetime &time[],

                const double &open[],

                const double& high[],     // F5=>2>9 <0AA82 <0:A8<C<>2 F5=K 4;O @0AGQB0 8=48:0B>@0

                const double& low[],      // F5=>2>9 <0AA82 <8=8<C<>2 F5=K  4;O @0AGQB0 8=48:0B>@0

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[]

                )

  {

//---- ?@>25@:0 :>;8G5AB20 10@>2 =0 4>AB0B>G=>ABL 4;O @0AGQB0

   if(rates_total<min_rates_total) return(0);



//---- 1JO2;5=85 ;>:0;L=KE ?5@5<5==KE

   int first,bar;

   double res[9],PEMA,trend;



   if(prev_calculated>rates_total || prev_calculated<=0) // ?@>25@:0 =0 ?5@2K9 AB0@B @0AGQB0 8=48:0B>@0

     {

      first=0; // AB0@B>2K9 =><5@ 4;O @0AGQB0 2A5E 10@>2

     }

   else first=prev_calculated-1; // AB0@B>2K9 =><5@ 4;O @0AGQB0 =>2KE 10@>2

   

//---- 8=45:A0F8O M;5<5=B>2 2 <0AA820E =5 :0: 2 B09<A5@8OE  

   ArraySetAsSeries(open,false);

   ArraySetAsSeries(high,false);

   ArraySetAsSeries(low,false);

   ArraySetAsSeries(close,false);



//---- >A=>2=>9 F8:; @0AGQB0 8=48:0B>@0

   for(bar=first; bar<rates_total && !IsStopped(); bar++)

     {

      res[0]=PriceSeries(IPC,bar,open,low,high,close);

      res[1]=EMA[0].EMASeries(0,prev_calculated,rates_total,EmaLength,res[0],bar,false); 

      res[2]=EMA[1].EMASeries(1,prev_calculated,rates_total,EmaLength,res[1],bar,false); 

      res[3]=EMA[2].EMASeries(2,prev_calculated,rates_total,EmaLength,res[2],bar,false); 

      res[4]=EMA[3].EMASeries(3,prev_calculated,rates_total,EmaLength,res[3],bar,false); 

      res[5]=EMA[4].EMASeries(4,prev_calculated,rates_total,EmaLength,res[4],bar,false); 

      res[6]=EMA[5].EMASeries(5,prev_calculated,rates_total,EmaLength,res[5],bar,false); 

      res[7]=EMA[6].EMASeries(6,prev_calculated,rates_total,EmaLength,res[6],bar,false); 

      res[8]=EMA[7].EMASeries(7,prev_calculated,rates_total,EmaLength,res[7],bar,false);    

      PEMA=8*res[1]-28*res[2]+56*res[3]-70*res[4]+56*res[5]-28*res[6]+8*res[7]-res[8];

      ExtLineBuffer[bar]=PointPow10*MathRound(PEMA/PointPow10)+dPriceShift;  

     }

//---- >B>1@065=85 F5=>2>9 <5B:8

   if(ShowPrice)

     {

      int bar0=rates_total-1;

      datetime time0=time[bar0]+1*PeriodSeconds();

      SetRightPrice(0,Price_name,0,time0,ExtLineBuffer[bar0],Price_color);

     }

//---- :>@@5:B8@>2:0 7=0G5=8O ?5@5<5==>9 first

   if(prev_calculated>rates_total || prev_calculated<=0) // ?@>25@:0 =0 ?5@2K9 AB0@B @0AG5B0 8=48:0B>@0

      first++; // AB0@B>2K9 =><5@ 4;O @0AG5B0 2A5E 10@>2



//---- A=>2=>9 F8:; @0A:@0A:8 A83=0;L=>9 ;8=88

   for(bar=first; bar<rates_total && !IsStopped(); bar++)

     {

      double clr=ColorExtLineBuffer[bar-1];

      trend=ExtLineBuffer[bar]-ExtLineBuffer[bar-1];

      if(trend>0) clr=1;

      if(trend<0) clr=0;

      ColorExtLineBuffer[bar]=clr;

     }

//----

   ChartRedraw(0);

   return(rates_total);

  }

//+------------------------------------------------------------------+

//|  RightPrice creation                                             |

//+------------------------------------------------------------------+

void CreateRightPrice(long chart_id,// chart ID

                      string   name,              // object name

                      int      nwin,              // window index

                      datetime time,              // price level time

                      double   price,             // price level

                      color    Color              // Text color

                      )

//---- 

  {

//----

   ObjectCreate(chart_id,name,OBJ_ARROW_RIGHT_PRICE,nwin,time,price);

   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);

   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true);

   ObjectSetInteger(chart_id,name,OBJPROP_WIDTH,2);

//----

  }

//+------------------------------------------------------------------+

//|  RightPrice reinstallation                                       |

//+------------------------------------------------------------------+

void SetRightPrice(long chart_id,// chart ID

                   string   name,              // object name

                   int      nwin,              // window index

                   datetime time,              // price level time

                   double   price,             // price level

                   color    Color              // Text color

                   )

//---- 

  {

//----

   if(ObjectFind(chart_id,name)==-1) CreateRightPrice(chart_id,name,nwin,time,price,Color);

   else ObjectMove(chart_id,name,0,time,price);

//----

  }

//+------------------------------------------------------------------+