colorjfatlspeed_v1

//+---------------------------------------------------------------------+
//|                                                 ColorJFatlSpeed.mq5 | 
//|                                 èCopyright © 2010, Nikolay Kositsin | 
//|                                 Khabarovsk,   farria@mail.redcom.ru | 
//+---------------------------------------------------------------------+ 
//| Äëÿ ðàáîòû  èíäèêàòîðà  ñëåäóåò  ïîëîæèòü ôàéë SmoothAlgorithms.mqh |
//| â ïàïêó (äèðåêòîðèþ): êàòàëîã_äàííûõ_òåðìèíàëà\\MQL5\Include        |
//+---------------------------------------------------------------------+
#property copyright "2010,   Nikolay Kositsin"
#property link      "farria@mail.redcom.ru"
#property version   "1.11"
//---- îòðèñîâêà èíäèêàòîðà â îòäåëüíîì îêíå
#property indicator_separate_window 
//---- äëÿ ðàñ÷åòà è îòðèñîâêè èíäèêàòîðà èñïîëüçîâàíî òðè áóôåðà
#property indicator_buffers 3
//---- èñïîëüçîâàíî âñåãî äâà ãðàôè÷åñêèõ ïîñòðîåíèÿ
#property indicator_plots   2
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 1             |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå ëèíèè
#property indicator_type1   DRAW_LINE
//---- â êà÷åñòâå öâåòîâ èíäèêàòîðà èñïîëüçîâàí ñåðûé öâåò
#property indicator_color1  clrGray
//---- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style1  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 2
#property indicator_width1  2
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label1  "JFATL SPEED"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 2             |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå çíà÷êà
#property indicator_type2   DRAW_COLOR_ARROW
//---- â êà÷åñòâå öâåòîâ èíäèêàòîðà èñïîëüçîâàíû ñåðûé, ñèíèé è ðîçîâûé öâåòà
#property indicator_color2  clrMagenta,clrGray,clrBlue
//---- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style2  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 2
#property indicator_width2  2
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label2  "JFATL SPEED"
//+----------------------------------------------+
//| Îáúÿâëåíèå ïåðå÷èñëåíèé                      |
//+----------------------------------------------+
enum Applied_price_ //òèï êîíñòàíòû
  {
   PRICE_CLOSE_ = 1,     //Close
   PRICE_OPEN_,          //Open
   PRICE_HIGH_,          //High
   PRICE_LOW_,           //Low
   PRICE_MEDIAN_,        //Median Price (HL/2)
   PRICE_TYPICAL_,       //Typical Price (HLC/3)
   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
   PRICE_SIMPL_,         //Simpl Price (OC/2)
   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
   PRICE_DEMARK_         //Demark Price
  };
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+
input int JLength=8;   // Ïåðèîä JMA ñãëàæèâàíèÿ Fatl                   
input int JPhase=100;  // Ïàðàìåòð JMA ñãëàæèâàíèÿ Fatl
                       // èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100,
                       // âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà
input int MomPeriod=1; // Ïåðèîä èíäèêàòîðà Momentum äëÿ èçìåðåíèÿ ñêîðîñòè

input int Smooth=2;    // Ãëóáèíà JMA ñãëàæèâàíèÿ èíäèêàòîðà                  
input int SmPhase=100; // Ïàðàìåòð JMA ñãëàæèâàíèÿ èíäèêàòîðà
                       // èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100,
                       // âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà
input Applied_price_ IPC=PRICE_CLOSE_; // Öåíîâàÿ êîíñòàíòà
input int FATLShift=0; // Ñäâèã èíäèêàòîðà ïî ãîðèçîíòàëè â áàðàõ
//+----------------------------------------------+
//---- îáúÿâëåíèå è èíèöèàëèçàöèÿ ïåðåìåííîé äëÿ õðàíåíèÿ êîëè÷åñòâà ðàñ÷åòíûõ áàðîâ FATL
int FATLPeriod=39;
//---- îáúÿâëåíèå äèíàìè÷åñêîãî ìàññèâîâ, êîòîðûå áóäóò â 
//---- äàëüíåéøåì èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double IndBuffer[];
double ColorBuffer[];
double LineIndBuffer[];
//----
int start,fstart,jfstart,mstart,FATLSize;
double dPriceShift;
//+------------------------------------------------------------------+
//| Îïèñàíèå ôóíêöèè iPriceSeries()                                  |
//| Îïèñàíèå êëàññîâ CFATL, CJJMA è CMomentum                        |
//+------------------------------------------------------------------+ 
#include <SmoothAlgorithms.mqh>  
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+ 
void OnInit()
  {
//---- èíèöèàëèçàöèÿ ïåðåìåííûõ
   fstart=FATLPeriod;
   jfstart=fstart+30;
   mstart=jfstart+MomPeriod;
   start=mstart+30+1;
//---- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà IndBuffer â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(0,LineIndBuffer,INDICATOR_DATA);
//---- îñóùåñòâëåíèå ñäâèãà èíäèêàòîðà ïî ãîðèçîíòàëè íà FATLShift
   PlotIndexSetInteger(0,PLOT_SHIFT,FATLShift);
//---- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷åòà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,start);
//--- çàïðåò íà îòðèñîâêó èíäèêàòîðîì ïóñòûõ çíà÷åíèé
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
//---- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà IndBuffer â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(1,IndBuffer,INDICATOR_DATA);
//---- îñóùåñòâëåíèå ñäâèãà èíäèêàòîðà ïî ãîðèçîíòàëè íà FATLShift
   PlotIndexSetInteger(1,PLOT_SHIFT,FATLShift);
//---- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷åòà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,start);
//--- çàïðåò íà îòðèñîâêó èíäèêàòîðîì ïóñòûõ çíà÷åíèé
   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);
//--- âûáîð ñèìâîëà äëÿ îòðèñîâêè
   PlotIndexSetInteger(1,PLOT_ARROW,159);
//---- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â öâåòîâîé, èíäåêñíûé áóôåð   
   SetIndexBuffer(2,ColorBuffer,INDICATOR_COLOR_INDEX);
//---- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷åòà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(2,PLOT_DRAW_BEGIN,start);
//---- èíèöèàëèçàöèÿ ïåðåìåííîé äëÿ êîðîòêîãî èìåíè èíäèêàòîðà
   string shortname;
   StringConcatenate(shortname,"JFATL Speed(",JLength," ,",JPhase," ,",MomPeriod,")");
//--- ñîçäàíèå èìåíè äëÿ îòîáðàæåíèÿ â îòäåëüíîì ïîäîêíå è âî âñïëûâàþùåé ïîäñêàçêå
   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
//--- îïðåäåëåíèå òî÷íîñòè îòîáðàæåíèÿ çíà÷åíèé èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,0);
//---- îáúÿâëåíèå ïåðåìåííîé êëàññà CJJMA èç ôàéëà JJMASeries_Cls.mqh
   CJJMA JMA;
//---- óñòàíîâêà àëåðòîâ íà íåäîïóñòèìûå çíà÷åíèÿ âíåøíèõ ïåðåìåííûõ
   JMA.JJMALengthCheck("JLength", JLength);
   JMA.JJMAPhaseCheck("JPhase", JPhase);
   JMA.JJMALengthCheck("MomPeriod", MomPeriod);
   JMA.JJMALengthCheck("Smooth", Smooth);
   JMA.JJMAPhaseCheck("SmPhase", SmPhase);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,    // êîëè÷åñòâî èñòîðèè â áàðàõ íà òåêóùåì òèêå
                const int prev_calculated,// êîëè÷åñòâî èñòîðèè â áàðàõ íà ïðåäûäóùåì òèêå
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷åòà
   if(rates_total<start) return(0);
//---- îáúÿâëåíèÿ ëîêàëüíûõ ïåðåìåííûõ 
   int first,bar,clr;
   double price,jfatl,fatl,jmom,jfspeed;
//---- ðàñ÷åò ñòàðòîâîãî íîìåðà first äëÿ öèêëà ïåðåñ÷åòà áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0) // ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷åòà èíäèêàòîðà
     {
      first=0; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà âñåõ áàðîâ
     }
   else first=prev_calculated-1; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà íîâûõ áàðîâ
//---- îáúÿâëåíèå ïåðåìåííûõ êëàññîâ CFATL, CJJMA è CMomentum èç ôàéëà JJMASeries_Cls.mqh
   static CJJMA JMA1,JMA2;
   static CFATL FATL;
   static CMomentum MOM;
//---- îñíîâíîé öèêë ðàñ÷åòà èíäèêàòîðà
   for(bar=first; bar<rates_total; bar++)
     {
      //---- ïîëó÷àåì âõîäíóþ öåíó price
      price=PriceSeries(IPC,bar,open,low,high,close);
      //---- ãðóçèì âõîäíóþ öåíó price â FATLSeries() è ïîëó÷àåì fatl
      fatl=FATL.FATLSeries(0,prev_calculated,rates_total,price,bar,false);
      //---- ãðóçèì fatl â JJMASeries() è ïîëó÷àåì jfatl
      jfatl=JMA1.JJMASeries(fstart,prev_calculated,rates_total,0,JPhase,JLength,fatl,bar,false);
      //---- ãðóçèì jfatl â MomentumSeries() è ïîëó÷àåì jmom
      jmom=MOM.MomentumSeries(jfstart,prev_calculated,rates_total,MomPeriod,jfatl,bar,false);
      //---- ãðóçèì jmom â JJMASeries() è ïîëó÷àåì jfspeed
      jfspeed=JMA2.JJMASeries(mstart,prev_calculated,rates_total,0,SmPhase,Smooth,jmom,bar,false);
      //---- ìåíÿåì ðàçìåðíîñòü èíäèêàòîðà äî öåëûõ çíà÷åíèé
      jfspeed/=_Point;
      //---- ãðóçèì jfspeed â èíäèêàòîðíûé áóôåð
      IndBuffer[bar]=jfspeed;
      LineIndBuffer[bar]=jfspeed;
     }
//---- êîððåêòèðóåì çíà÷åíèå ñòàðòîâîãî íîìåðà äëÿ ðàñ÷åòà âñåõ áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0) first=start;
//---- îñíîâíîé öèêë ðàñêðàñêè ñèãíàëüíîé ëèíèè
   for(bar=first; bar<rates_total; bar++)
     {
      clr=1;
      if(IndBuffer[bar]>IndBuffer[bar-1]) clr=2;
      if(IndBuffer[bar]<IndBuffer[bar-1]) clr=0;
      ColorBuffer[bar]=clr;
     }
//----     
   return(rates_total);
  }
//+------------------------------------------------------------------+