exp_slopedirectionline

//+------------------------------------------------------------------+
//|                                       Exp_SlopeDirectionLine.mq5 |
//|                             Copyright © 2012,   Nikolay Kositsin | 
//|                              Khabarovsk,   farria@mail.redcom.ru | 
//+------------------------------------------------------------------+
#property copyright "Copyright © 2012, Nikolay Kositsin"
#property link      "farria@mail.redcom.ru"
#property version   "1.00"
//+-------------------------------------------------+
//| Òîðãîâûå àëãîðèòìû                              |
//+-------------------------------------------------+
#include <TradeAlgorithms.mqh>
//+-------------------------------------------------+
//| Ïåðå÷èñëåíèå äëÿ âàðèàíòîâ ðàñ÷¸òà ëîòà         |
//+-------------------------------------------------+
/*enum MarginMode  - ïåðå÷èñëåíèå îáúÿâëåíî â ôàéëå TradeAlgorithms.mqh
  {
   FREEMARGIN=0,     //MM îò ñâîáîäíûõ ñðåäñòâ íà ñ÷¸òå
   BALANCE,          //MM îò áàëàíñà ñðåäñòâ íà ñ÷¸òå
   LOSSFREEMARGIN,   //MM ïî óáûòêàì îò ñâîáîäíûõ ñðåäñòâ íà ñ÷¸òå
   LOSSBALANCE,      //MM ïî óáûòêàì îò áàëàíñà ñðåäñòâ íà ñ÷¸òå
   LOT               //Ëîò áåç èçìåíåíèÿ
  }; */
//+-------------------------------------------------+
//| Îïèñàíèå êëàññà CXMA                            |
//+-------------------------------------------------+
#include <SmoothAlgorithms.mqh> 
//+-------------------------------------------------+
//| îáúÿâëåíèå ïåðå÷èñëåíèé                         |
//+-------------------------------------------------+
enum Applied_price_ //Òèï êîíñòàíòû
  {
   PRICE_CLOSE_ = 1,     //Close
   PRICE_OPEN_,          //Open
   PRICE_HIGH_,          //High
   PRICE_LOW_,           //Low
   PRICE_MEDIAN_,        //Median Price (HL/2)
   PRICE_TYPICAL_,       //Typical Price (HLC/3)
   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
   PRICE_SIMPL_,         //Simple Price (OC/2)
   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price 
   PRICE_DEMARK_         //Demark Price 
  };
//+-------------------------------------------------+
//| îáúÿâëåíèå ïåðå÷èñëåíèé                         |
//+-------------------------------------------------+
/*
enum Smooth_Method
  {
   MODE_SMA_,  //SMA
   MODE_EMA_,  //EMA
   MODE_SMMA_, //SMMA
   MODE_LWMA_, //LWMA
   MODE_JJMA,  //JJMA
   MODE_JurX,  //JurX
   MODE_ParMA, //ParMA
   MODE_T3,    //T3
   MODE_VIDYA, //VIDYA
   MODE_AMA,   //AMA
  };
*/
//+-------------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà ýêñïåðòà           |
//+-------------------------------------------------+
input double MM=0.1;              // Äîëÿ ôèíàíñîâûõ ðåñóðñîâ îò äåïîçèòà â ñäåëêå
input MarginMode MMMode=LOT;      // Cïîñîá îïðåäåëåíèÿ ðàçìåðà ëîòà
input int    StopLoss_=1000;      // Stop Loss â ïóíêòàõ
input int    TakeProfit_=2000;    // Take Profit â ïóíêòàõ
input int    Deviation_=10;       // Ìàêñ. îòêëîíåíèå öåíû â ïóíêòàõ
input bool   BuyPosOpen=true;     // Ðàçðåøåíèå äëÿ âõîäà â ëîíã
input bool   SellPosOpen=true;    // Ðàçðåøåíèå äëÿ âõîäà â øîðò
input bool   BuyPosClose=true;    // Ðàçðåøåíèå äëÿ âûõîäà èç ëîíãîâ
input bool   SellPosClose=true;   // Ðàçðåøåíèå äëÿ âûõîäà èç øîðòîâ
//+-------------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà SlopeDirectionLine |
//+-------------------------------------------------+
input ENUM_TIMEFRAMES InpInd_Timeframe=PERIOD_H4;     // Òàéìôðåéì èíäèêàòîðà
input Smooth_Method MA_Method1=MODE_LWMA;             // Ìåòîä ïåðâîãî óñðåäíåíèÿ
input uint Length1=12;                                // Ãëóáèíà ïåðâîãî óñðåäíåíèÿ
input int Phase1=15;                                  // Ïàðàìåòð ïåðâîãî óñðåäíåíèÿ
//--- Phase1: äëÿ JJMA èçìåíÿåòñÿ â ïðåäåëàõ -100..+100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//--- Phase1: äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input Smooth_Method MA_Method2=MODE_SMA;              // Ìåòîä óñðåäíåíèÿ âòîðîãî ñãëàæèâàíèÿ 
input int Phase2=15;                                  // Ïàðàìåòð âòîðîãî ñãëàæèâàíèÿ
//--- Phase2: äëÿ JJMA èçìåíÿåòñÿ â ïðåäåëàõ -100..+100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//--- Phase2: äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input Applied_price_ IPC=PRICE_CLOSE;                 // Öåíîâàÿ êîíñòàíòà
input bool On_Push = false;                           // Ðàçðåøåíèå íà ïåðåäà÷ó push-ñîîáùåíèé
input bool On_Email = false;                          // Ðàçðåøåíèå íà îòïðàâêó ïî÷òû
input bool On_Alert = true;                           // Ðàçðåøåíèå íà ïîäà÷ó àëåðòà
input bool On_Play_Sound = false;                     // Ðàçðåøåíèå íà ïîäà÷ó çâóêîâîãî ñèãíàëà
input string NameFileSound = "expert.wav";            // Èìÿ äëÿ ôàéëà çâóêîâîãî ñèãíàëà
input string  CommentSirName="SlopeDirectionLine: ";  // Ïåðâàÿ ÷àñòü àëåðò-êîììåíòà
input uint SignalBar=1;                               // Íîìåð áàðà äëÿ ñèãíàëà
//+-------------------------------------------------+
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ äëÿ õðàíåíèÿ ïåðèîäà ãðàôèêà â ñåêóíäàõ 
int TimeShiftSec;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ äëÿ õåíäëîâ èíäèêàòîðîâ
int InpInd_Handle;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
int min_rates_total;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà SlopeDirectionLine
   InpInd_Handle=iCustom(Symbol(),InpInd_Timeframe,"SlopeDirectionLine",MA_Method1,Length1,Phase1,MA_Method2,Phase2,IPC,0,0,false,false,false,false,"","",0);
   if(InpInd_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà SlopeDirectionLine");
      return(INIT_FAILED);
     }
//--- èíèöèàëèçàöèÿ ïåðåìåííîé äëÿ õðàíåíèÿ ïåðèîäà ãðàôèêà â ñåêóíäàõ  
   TimeShiftSec=PeriodSeconds(InpInd_Timeframe);
//--- èíèöèàëèçàöèÿ ïåðåìåííûõ íà÷àëà îòñ÷¸òà äàííûõ
   int LengthR=int(MathMax(MathSqrt(Length1),1));
   min_rates_total+=GetStartBars(MA_Method1,Length1,Phase1);
   min_rates_total+=GetStartBars(MA_Method2,LengthR,Phase2);
   min_rates_total+=int(2+SignalBar);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   GlobalVariableDel_(Symbol());
//---
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷¸òà
   if(BarsCalculated(InpInd_Handle)<min_rates_total) return;
//--- ïîäãðóçêà èñòîðèè äëÿ íîðìàëüíîé ðàáîòû ôóíêöèé IsNewBar() è SeriesInfoInteger()  
   LoadHistory(TimeCurrent()-PeriodSeconds(InpInd_Timeframe)-1,Symbol(),InpInd_Timeframe);
//--- îáúÿâëåíèå ëîêàëüíûõ ïåðåìåííûõ
   double Value[2];
//--- îáúÿâëåíèå ñòàòè÷åñêèõ ïåðåìåííûõ
   static bool Recount=true;
   static bool BUY_Open=false,BUY_Close=false;
   static bool SELL_Open=false,SELL_Close=false;
   static datetime UpSignalTime,DnSignalTime;
   static CIsNewBar NB;
//--- îïðåäåëåíèå ñèãíàëîâ äëÿ ñäåëîê
   if(!SignalBar || NB.IsNewBar(Symbol(),InpInd_Timeframe) || Recount) // ïðîâåðêà íà ïîÿâëåíèå íîâîãî áàðà
     {
      //--- îáíóëèì òîðãîâûå ñèãíàëû
      BUY_Open=false;
      SELL_Open=false;
      BUY_Close=false;
      SELL_Close=false;
      Recount=false;
      //--- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâû
      if(CopyBuffer(InpInd_Handle,1,SignalBar,2,Value)<=0) {Recount=true; return;}
      //--- ïîëó÷èì ñèãíàëû äëÿ ïîêóïêè
      if(Value[1]==2)
        {
         if(BuyPosOpen && Value[0]!=2) BUY_Open=true;
         if(SellPosClose) SELL_Close=true;
         UpSignalTime=datetime(SeriesInfoInteger(Symbol(),InpInd_Timeframe,SERIES_LASTBAR_DATE))+TimeShiftSec;
        }
      //--- ïîëó÷èì ñèãíàëû äëÿ ïðîäàæè
      if(Value[1]==0)
        {
         if(SellPosOpen&&Value[0]!=0) SELL_Open=true;
         if(BuyPosClose) BUY_Close=true;
         DnSignalTime=datetime(SeriesInfoInteger(Symbol(),InpInd_Timeframe,SERIES_LASTBAR_DATE))+TimeShiftSec;
        }
     }
//--- ñîâåðøåíèå ñäåëîê
//--- çàêðûâàåì ëîíã
   BuyPositionClose(BUY_Close,Symbol(),Deviation_);
//--- çàêðûâàåì øîðò   
   SellPositionClose(SELL_Close,Symbol(),Deviation_);
//--- îòêðûâàåì ëîíã
   BuyPositionOpen(BUY_Open,Symbol(),UpSignalTime,MM,MMMode,Deviation_,StopLoss_,TakeProfit_);
//--- îòêðûâàåì øîðò
   SellPositionOpen(SELL_Open,Symbol(),DnSignalTime,MM,MMMode,Deviation_,StopLoss_,TakeProfit_);
//---
  }
//+------------------------------------------------------------------+