FrAMA Color N Bars

ÿþ//+------------------------------------------------------------------+

//|                                           FrAMA Color N Bars.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 2

#property indicator_plots   1

//--- plot MAColor

#property indicator_label1  "FrAMAColor"

#property indicator_type1   DRAW_COLOR_LINE

#property indicator_color1  clrYellowGreen,clrBlue,clrRed

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- input parameters

input int                  Inp_FrAMA_ma_period     = 14;          // FrAMA: averaging period

input int                  Inp_FrAMA_ma_shift      = 0;           // FrAMA: horizontal shift of indicator

input ENUM_APPLIED_PRICE   Inp_FrAMA_applied_price = PRICE_CLOSE; // FrAMA: type of price

input uchar                Inp_MA_trend_n_bars     = 3;           // FrAMA: trend N Bars

//--- indicator buffers

double   FrAMAColorBuffer[];

double   FrAMAColorColors[];

//---

int      handle_iFrAMA;                         // variable for storing the handle of the iFrAMA indicator

int      bars_calculated   = 0;                 // we will keep the number of values in the Fractal Adaptive Moving Average indicator

bool     m_init_error      = false;             // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,FrAMAColorBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,FrAMAColorColors,INDICATOR_COLOR_INDEX);

//--- set shift

   PlotIndexSetInteger(0,PLOT_SHIFT,Inp_FrAMA_ma_shift);

//--- create handle of the indicator

   handle_iFrAMA=iFrAMA(Symbol(),Period(),Inp_FrAMA_ma_period,

                        Inp_FrAMA_ma_shift,Inp_FrAMA_applied_price);

//--- if the handle is not created

   if(handle_iFrAMA==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iFrAMA indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- show the symbol/timeframe the Moving Average indicator is calculated for

   string short_name=StringFormat("FrAMA Color(%d, %d, %s, %d)",

                                  Inp_FrAMA_ma_period, Inp_FrAMA_ma_shift,

                                  EnumToString(Inp_FrAMA_applied_price),Inp_MA_trend_n_bars);

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(m_init_error)

      return(0);

   if(rates_total<=Inp_FrAMA_ma_period+Inp_FrAMA_ma_shift+Inp_MA_trend_n_bars)

      return(0);

//---

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iFrAMA);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iFrAMA indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iFrAMABuffer array is greater than the number of values in the iFrAMA indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iFrAMABuffer array with values of the Fractal Adaptive Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(FrAMAColorBuffer,Inp_FrAMA_ma_shift,handle_iFrAMA,values_to_copy))

      return(0);

//--- memorize the number of values in the Fractal Adaptive Moving Average indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=Inp_FrAMA_ma_period+Inp_FrAMA_ma_shift+Inp_MA_trend_n_bars;

      for(int i=0; i<limit; i++)

         FrAMAColorColors[i]=0.0;

     }

   for(int i=limit; i<rates_total; i++)

     {

      int trend=0;

      for(int j=i-Inp_MA_trend_n_bars; j<i; j++)

        {

         if(FrAMAColorBuffer[j]<FrAMAColorBuffer[j+1])

            trend++;

         else

            trend--;

        }

      if(trend==Inp_MA_trend_n_bars)

         FrAMAColorColors[i]=1;

      else

         if(-trend==Inp_MA_trend_n_bars)

            FrAMAColorColors[i]=2;

         else

            FrAMAColorColors[i]=0;

      int d=0;

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+ 

//| Filling indicator buffers from the iFrAMA indicator              | 

//+------------------------------------------------------------------+ 

bool FillArrayFromBuffer(double &values[],  // indicator buffer of Fractal Adaptive Moving Average values 

                         int shift,         // shift 

                         int ind_handle,    // handle of the iFrAMA indicator 

                         int amount         // number of copied values 

                         ) 

  { 

//--- reset error code 

   ResetLastError(); 

//--- fill a part of the iFrAMABuffer array with values from the indicator buffer that has 0 index 

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0) 

     { 

      //--- if the copying fails, tell the error code 

      PrintFormat("Failed to copy data from the iFrAMA indicator, error code %d",GetLastError()); 

      //--- quit with zero result - it means that the indicator is considered as not calculated 

      return(false); 

     } 

//--- everything is fine 

   return(true); 

  } 

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iFrAMA!=INVALID_HANDLE)

      IndicatorRelease(handle_iFrAMA);

  }

//+------------------------------------------------------------------+