Half Bar Protection

ÿþ//+------------------------------------------------------------------+

//|                                          Half Bar Protection.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

/*

   barabashkakvn Trading engine 3.119

*/

#include <Trade\PositionInfo.mqh>

#include <Trade\Trade.mqh>

#include <Trade\SymbolInfo.mqh>

//---

CPositionInfo  m_position;                      // object of CPositionInfo class

CTrade         m_trade;                         // object of CTrade class

CSymbolInfo    m_symbol;                        // object of CSymbolInfo class

//--- input parameters

input uint     InpMinimumBarHeight  = 15;       // Minimum bar height, in pips (1.00045-1.00055=1 pips)

input ulong    InpDeviation         = 10;       // Deviation, in points (1.00045-1.00055=10 points)

//---

double   m_minimum_bar_height       = 0.0;      // Minimum bar height      -> double



double   m_adjusted_point;                      // point value adjusted for 3 or 5 points

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int OnInit()

  {

//---

   if(!m_symbol.Name(Symbol())) // sets symbol name

     {

      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");

      return(INIT_FAILED);

     }

   RefreshRates();

//---

      m_trade.SetExpertMagicNumber(0);

   m_trade.SetMarginMode();

   m_trade.SetTypeFillingBySymbol(m_symbol.Name());

   m_trade.SetDeviationInPoints(InpDeviation);

//--- tuning for 3 or 5 digits

   int digits_adjust=1;

   if(m_symbol.Digits()==3 || m_symbol.Digits()==5)

      digits_adjust=10;

   m_adjusted_point=m_symbol.Point()*digits_adjust;



   m_minimum_bar_height    = InpMinimumBarHeight   * m_adjusted_point;

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert deinitialization function                                 |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

//---



  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void OnTick()

  {

   MqlRates rates[];

   ArraySetAsSeries(rates,true);

   int start_pos=0,count=3;

   if(CopyRates(m_symbol.Name(),Period(),start_pos,count,rates)!=count)

      return;

   if(MathAbs(rates[1].open-rates[1].close)<m_minimum_bar_height)

      return;

//---

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of open positions

      if(m_position.SelectByIndex(i))

         if(m_position.Symbol()==m_symbol.Name())

           {

            double half_price=MathAbs(rates[1].open+rates[1].close)/2.0;



            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               if(m_position.Profit()>0.0)

                  if(m_position.PriceCurrent()<=half_price)

                     m_trade.PositionClose(m_position.Ticket());

              }

            else

              {

               if(m_position.Profit()>0.0)

                  if(m_position.PriceCurrent()>=half_price)

                     m_trade.PositionClose(m_position.Ticket());

              }

           }

  }

//+------------------------------------------------------------------+

//| Refreshes the symbol quotes data                                 |

//+------------------------------------------------------------------+

bool RefreshRates()

  {

//--- refresh rates

   if(!m_symbol.RefreshRates())

      return(false);

//--- protection against the return value of "zero"

   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)

      return(false);

//---

   return(true);

  }

//+------------------------------------------------------------------+