MACD(2lines)

ÿþ//+------------------------------------------------------------------+

//|                                                     MACD2017.mq4 |

//|                                         Copyright 2017, fxMeter. |

//|                            https://www.mql5.com/zh/users/fxmeter |

//+------------------------------------------------------------------+

//2017-04-27 13:54:38 	cgqýV…Q¡€hyoöN¾áO-N„vMACDlQ_™Q

/*

SHORT=12,LONG=26,MID=9

DIF:EMA(CLOSE,SHORT)-EMA(CLOSE,LONG);

DEA:EMA(DIF,MID);

MACD:(DIF-DEA)*2,COLORSTICK;



ô‹f:

ýV…QŠb DIF-DEAëSMACD(;ubñgP[)

€ž[E–
NýVE–
NÿSìbMT4„v…QnlQ_-Ný/fŠbDIFëSMACD(;ubñgP[),ŠbDEAëSSignal,¡l	g(DIF-DEA)*2

œ˜r‚	cgq¾áOMCADM‘n

*/

#property copyright "Copyright 2017,fxMeter."

#property link      "https://www.mql5.com/zh/users/fxmeter"

#property version   "2.00"

#property strict

#property indicator_separate_window

#property indicator_buffers 4

#property indicator_plots   4

//--- plot DIF

#property indicator_label1  "DIF"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrSilver

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot DEA

#property indicator_label2  "DEA"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrYellow

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot macd hist+

#property indicator_label3  "Macd+"

#property indicator_type3   DRAW_HISTOGRAM

#property indicator_color3  clrRed

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- plot macd hist-

#property indicator_label4  "Macd-"

#property indicator_type4   DRAW_HISTOGRAM

#property indicator_color4  clrAqua

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1





input int FastEMA = 12;

input int SlowEMA = 26;

input int MACDEMA = 9;





//--- indicator buffers

double         DIFBuffer[];

double         DEABuffer[];

double         MacdHistBuffer[];

double         MacdHistBuffer1[];

double w=0;

double w1=0;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

{

//--- indicator buffers mapping

   SetIndexBuffer(0,DIFBuffer);

   SetIndexBuffer(1,DEABuffer);

   SetIndexBuffer(2,MacdHistBuffer);

   SetIndexBuffer(3,MacdHistBuffer1);



   for(int i=0; i<4; i++)

   {

      SetIndexEmptyValue(i,0);

      SetIndexDrawBegin(i,3);

   }





   IndicatorDigits(Digits);



   IndicatorShortName("MACD("+(string)FastEMA+","+(string)SlowEMA+","+(string)MACDEMA+")");



   if(FastEMA<0 || SlowEMA<0 || MACDEMA<0)

      return(INIT_FAILED);



   w = 2.0/(MACDEMA + 1);

   w1= 1.0-w;



//---

   return(INIT_SUCCEEDED);

}

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

{

//---

   int i,limit=0;

   if(rates_total<=0) return(0);

   if(prev_calculated<=0) limit=rates_total-1;

   else limit=rates_total-prev_calculated+1;

   double hst=0.0;

   for(i=limit; i>=0; i--)

   {

      if(i>=rates_total-1)

      {

         DIFBuffer[i] = DEABuffer[i] = MacdHistBuffer[i] = MacdHistBuffer1[i] = 0;

         continue;

      }

      DIFBuffer[i]=iMA(NULL,0,FastEMA,0,MODE_EMA,PRICE_CLOSE,i)-iMA(NULL,0,SlowEMA,0,MODE_EMA,PRICE_CLOSE,i);

      DEABuffer[i]=w*DIFBuffer[i]+w1*DEABuffer[i+1];

      hst = 2.0*(DIFBuffer[i]-DEABuffer[i]);

      if(hst>=0)

      {

         MacdHistBuffer[i]=hst;

         MacdHistBuffer1[i]=0;

      }

      else

      {

         MacdHistBuffer1[i]=hst;

         MacdHistBuffer[i]=0;

      }



   }



//--- return value of prev_calculated for next call

   return(rates_total);

}

//+------------------------------------------------------------------+