RSI-TC_001

Download script
RSI-TC_001

This script is a specialized trading indicator designed to help market participants identify high-probability momentum shifts and trend breakouts by combining three primary technical analysis concepts: Relative Strength Index (RSI), Bollinger Bands, and Keltner Channels.

Core Logic Overview

The indicator functions by monitoring the relationship between price volatility and momentum. Instead of relying on a single metric, it looks for "coiled" market conditions—where price movement is suppressed—and then detects the exact moment that energy releases into a specific direction.

Key Components of the Logic:

1. Two-Tone RSI Momentum Tracking The script utilizes a modified Relative Strength Index (RSI) to visualize trend strength. Unlike a standard RSI which shows a continuous line, this logic creates a "Two-tone" effect. It distinguishes between bullish and bearish momentum by highlighting specific sections of the RSI line based on whether the price is maintaining strength above or below a designated midline. This allows traders to see at a glance whether the current momentum is leaning toward a buyer-led or seller-led environment.

2. The "Squeeze" Detection (Volatility Analysis) One of the most sophisticated parts of this script is its ability to identify a "Squeeze." It compares two different types of volatility envelopes:

  • Bollinger Bands: These contract based on standard deviation.
  • Keltner Channels: These expand based on Average True Range (ATR).

When the Bollinger Bands move inside the Keltner Channels, the script identifies a "Squeeze." In professional trading, this indicates that market volatility is extremely low and the price is being compressed like a spring. This state suggests that a significant breakout is imminent, though the direction is not yet determined.

3. Breakout Signal Generation The indicator generates visual signals (Buy/Sell arrows) by looking for a specific convergence of three events:

  • The Release: The market must exit a "Squeeze" state (moving from low volatility to high volatility).
  • The Momentum: The RSI must be on the correct side of the midpoint (above 50 for bullish, below 50 for bearish).
  • The Confirmation: A specific breach of the Bollinger Bands confirms that the price is moving with enough force to justify a trade.

Alert System

To ensure traders do not have to watch the charts constantly, the script includes an automated notification system. When the logic identifies a valid breakout—specifically when a new "Buy" or "Sell" signal appears on the current candle after a period of inactivity—it triggers a real-time alert. This allows for timely execution based on the technical conditions defined by the "Squeeze" and momentum filters.

Indicators Used
Relative strength indexMoving average indicatorBollinger bands indicatorIndicator of the average true range
Miscellaneous
Implements a curve of type %1It issuies visual alerts to the screen
15 Views
0 Downloads
0 Favorites
RSI-TC_001 
/*

*********************************************************************
          
                 RSI with Trend Catcher signal
                      
                              
                          by Matsu
              based on codes from various sources
                  
*********************************************************************

*/


#property indicator_separate_window
#property indicator_buffers 5
#property indicator_color1 Lime
#property indicator_color2 Red
#property indicator_color3 Lime
#property indicator_color4 Red
#property indicator_color5 Gold

#property indicator_level1 60
#property indicator_level2 50
#property indicator_level3 40

int       BBPrd=20;
double    BBDev=2.0;
int       SBPrd=13;
int       SBATRPrd=21;
double    SBFactor=2;
int       SBShift=1;
extern int       RSIPeriod=21;
extern int       BullLevel=50;
extern int       BearLevel=50;
extern bool      AlertOn = true;

double RSI[];
double DnRSI[];
double Buy[];
double Sell[];
double Squeeze[];



int init() 
{

   IndicatorBuffers(5);
   
   SetIndexStyle(0,DRAW_LINE);
   SetIndexBuffer(0,RSI);
   
   SetIndexStyle(1,DRAW_LINE);
   SetIndexBuffer(1,DnRSI);
   
   SetIndexStyle(2,DRAW_ARROW,STYLE_SOLID);
   SetIndexArrow(2,159);
   SetIndexBuffer(2,Buy);
   
   SetIndexStyle(3,DRAW_ARROW,STYLE_SOLID);
   SetIndexArrow(3,159);
   SetIndexBuffer(3,Sell);
   
   SetIndexStyle(4,DRAW_ARROW,STYLE_SOLID);
   SetIndexArrow(4,159);
   SetIndexBuffer(4,Squeeze);
      
   IndicatorShortName("RSI("+RSIPeriod+")");
   IndicatorDigits(2);
   
   return(0);
   
}



int start() 
{

   int counted_bars=IndicatorCounted();
   int shift,limit,ob,os;
   double BBMA, SBMA, TopBBand, BotBBand, TopBBandPrev, BotBBandPrev, TopSBand, BotSBand;
   bool dn = false;
   double BuyNow, BuyPrevious, SellNow, SellPrevious;
   static datetime prevtime = 0;
   
      
   if (counted_bars<0) return(-1);
   if (counted_bars>0) counted_bars--;
   limit=Bars-31;
   if(counted_bars>=31) limit=Bars-counted_bars-1;

   for (shift=limit;shift>=0;shift--)   
   {
            
      RSI[shift]=iRSI(NULL,0,RSIPeriod,PRICE_CLOSE,shift);
      ob = indicator_level1;
      os = indicator_level3;
      
      // ========= Two-tone RSI
      
      if (dn==true)
      {
         if (RSI[shift]>BullLevel) 
         {
            dn=false;
            DnRSI[shift]=EMPTY_VALUE;
         }
         else
         {
            dn=true;
            DnRSI[shift]=RSI[shift];
         }

      }
      else
      {
         if (RSI[shift]<BearLevel) 
         {
            dn=true;
            DnRSI[shift]=RSI[shift];
         }
         else
         {
            dn=false;
            DnRSI[shift]=EMPTY_VALUE;
         }
           
      }
      
      // ========= Two-tone RSI Ends
      
      // ========= Squeeze Signals
      
      BBMA     = iMA(NULL,0,BBPrd,0,MODE_SMA,PRICE_CLOSE,shift);
      SBMA     = iMA(NULL,0,SBPrd,0,MODE_EMA,PRICE_CLOSE,shift+SBShift);
      TopBBand = iBands(NULL,0,BBPrd,BBDev,0,PRICE_CLOSE,MODE_UPPER,shift);
	   BotBBand = iBands(NULL,0,BBPrd,BBDev,0,PRICE_CLOSE,MODE_LOWER,shift);
      TopSBand = SBMA + (SBFactor * iATR(NULL,0,SBATRPrd,shift+SBShift));
      BotSBand = SBMA - (SBFactor * iATR(NULL,0,SBATRPrd,shift+SBShift));
      TopBBandPrev = iBands(NULL,0,BBPrd,BBDev,0,PRICE_CLOSE,MODE_UPPER,shift+1);
	   BotBBandPrev = iBands(NULL,0,BBPrd,BBDev,0,PRICE_CLOSE,MODE_LOWER,shift+1);
      
      if (TopBBand<TopSBand && BotBBand>BotSBand) Squeeze[shift]=50;
      
      // ========= Squeeze Signals Ends
      
      // ========= BB Breakout Signals
      
      //if(Squeeze[shift+2]==50 && RSI[shift]>50 && BotBBand<BotSBand) 
      if((Squeeze[shift+2]==50 || Squeeze[shift+1]==50) && RSI[shift]>50 && BotBBand<BotSBand) 
      {
         Buy[shift]=ob;
         Sell[shift]=EMPTY_VALUE;
      } 
      else 
      //if(Squeeze[shift+2]==50 && RSI[shift]<50 && TopBBand>TopSBand) 
      if((Squeeze[shift+2]==50 || Squeeze[shift+1]==50) && RSI[shift]<50 && TopBBand>TopSBand) 
      {
         Buy[shift]=EMPTY_VALUE;
         Sell[shift]=os;
      }
      else
      if(Buy[shift+1]==ob && BotBBand<BotBBandPrev && RSI[shift]>50)
      {
         Buy[shift]=ob;
         Sell[shift]=EMPTY_VALUE;
      } 
      else
      if(Sell[shift+1]==os && TopBBand>TopBBandPrev && RSI[shift]<50)
      {
         Buy[shift]=EMPTY_VALUE;
         Sell[shift]=os;
      }
      else
      {
         Buy[shift]=EMPTY_VALUE;
         Sell[shift]=EMPTY_VALUE;
      }
      
      // ========= BB Breakout Signals Ends
      
   }      
         

   // ======= Alert =========

   if(AlertOn)
   {
      if(prevtime == Time[0]) 
      {
         return(0);
      }
      prevtime = Time[0];
   
      BuyNow = Buy[0];
      BuyPrevious = Buy[1];
      SellNow = Sell[0];
      SellPrevious = Sell[1];
   
      if((BuyNow ==ob) && (BuyPrevious ==EMPTY_VALUE) )
      {
         Alert(Symbol(), " M", Period(), " Buy Alert");
      }
      else   
      if((SellNow ==os) && (SellPrevious ==EMPTY_VALUE) )
      {
         Alert(Symbol(), " M", Period(), " Sell Alert");
      }
         
      IndicatorShortName("RSI("+RSIPeriod+") (Alert on)");

   }

   // ======= Alert Ends =========


   
   return(0);
   
}

Similar scripts

+RSI-TC

RSI-TC_NEW[1]

This indicator identifies high-probability momentum shifts by detecting price breakouts from low-volatility Keltner Channel squeezes while filtering directionality through a dual-tone Relative Strength Index.

RSI-TC

This indicator identifies high-probability trend reversals by detecting Bollinger Band contractions (squeezes) followed by price breakouts in alignment with multi-colored RSI momentum shifts.

RSI-TC_NEW

This indicator identifies explosive market entries by detecting volatility compression between Bollinger Bands and Keltner Channels, filtered by dual-tone RSI momentum and directional band breakouts.

RSI-TC_v1

This indicator identifies high-probability entries by synchronizing RSI momentum with the spatial divergence between Bollinger Bands and SuperTrend volatility envelopes.

RSI-TC_NEW1

This indicator identifies high-probability trend reversals by detecting volatility expansion from a 'squeeze' state combined with multi-layered RSI momentum filtering.

+RSI-TC_v2

RSI-TC_NEWd

This indicator identifies high-probability trend reversals by detecting price volatility compression using a Bollinger Band and Keltner Channel squeeze, coupled with RSI momentum filtering to trigger directional signals.

RSI-TC_NEW_v2

This indicator identifies high-probability trend continuations by detecting volatility 'squeezes' through Bollinger Band and Keltner Channel convergence, filtered by RSI momentum shifts.

MOM-TC_v2

This indicator identifies directional shifts by monitoring momentum breaches relative to a fixed level, generating visual signals and alerts upon trend reversals.

MOM-TC_NEW

This indicator identifies trend reversals by monitoring price velocity relative to a fixed 100-point threshold, generating visual signals and alerts upon direction flips.

Comments