Stochastic_Cross_Alert

Download script
Author: Copyright � 2006, Robert Hill
Stochastic_Cross_Alert

This tool is designed to act as a visual and audible signaling system for traders who use the Stochastic Oscillator to identify momentum shifts in the market. Instead of requiring you to constantly watch the charts for small line movements, this script automatically detects specific "crossovers" and highlights them with on-screen arrows and instant notifications.

Core Logic Overview

The script monitors two moving components of the Stochastic indicator: a "Fast" line (representing current momentum) and a "Slow" line (representing the signal). It looks for the exact moment these two lines intersect or cross over each other, which is often interpreted by traders as a potential entry or exit point.

How it Works

The logic follows a specific sequence of events to ensure you receive accurate information:

  • Momentum Detection: The script continuously calculates the current values and the previous values of both the Fast and Slow Stochastic lines.
  • Crossover Identification:
    • Buy Signals: It triggers when the Fast line moves from below the Slow line to above it.
    • Sell Signals: It triggers when the Fast line moves from above the Slow line to below it.
  • Dynamic Positioning: To ensure the visual signals are easy to see, the script calculates the "average range" of recent price action. It then places a Green Arrow below the price for Buy signals and a Red Arrow above the price for Sell signals, positioned at a distance that keeps them clear of the actual trading candles.
  • Alert System: To ensure you don't miss a trade while away from your screen, the script provides three layers of notification:
    1. Visual: Arrows appear directly on the chart.
    2. Audio: A pop-up sound alert triggers immediately upon a crossover.
    3. Email: If enabled, it sends a detailed email containing the specific price (Ask/Bid), the time of the trade, and the currency pair being monitored.

Key Features for Users

  • Real-Time Monitoring: The script scans every new price tick to ensure signals are captured as they happen.
  • Anti-Spam Logic: The script includes "flags" to ensure that you are only alerted once per signal, preventing your notifications from being flooded with repeated alerts on the same crossover.
  • Customizable Sensitivity: While the logic is automated, it allows for the standard Stochastic settings (K-Period, D-Period, and Slowing) to be adjusted so you can match the script to your specific trading style.
Price Data Components
Series array that contains open time of each bar
Indicators Used
Stochastic oscillator
Miscellaneous
Implements a curve of type %1It issuies visual alerts to the screenIt sends emails
10 Views
0 Downloads
0 Favorites
Stochastic_Cross_Alert 
//compile//
//+------------------------------------------------------------------+
//|                                       Stochastic_Cross_Alert.mq4 |
//|                         Copyright © 2006, Robert Hill            |
//|                                                                  |
//| Written Robert Hill for use with AIME for the stochastic cross   |
//| to draw arrows and popup alert or send email                     |
//+------------------------------------------------------------------+

#property copyright "Copyright © 2006, Robert Hill"

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_color1 LawnGreen
#property indicator_color2 Red
#property indicator_width1  2
#property indicator_width2  2

extern bool SoundON=true;
extern bool EmailON=false;
//---- input parameters
extern int KPeriod=5;
extern int DPeriod=3;
extern int Slowing=3;
extern int MA_Method = 0; // SMA 0, EMA 1, SMMA 2, LWMA 3
extern int PriceField = 0; // Low/High 0, Close/Close 1


double CrossUp[];
double CrossDown[];
int flagval1 = 0;
int flagval2 = 0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- indicators
   SetIndexStyle(0, DRAW_ARROW, EMPTY);
   SetIndexArrow(0, 233);
   SetIndexBuffer(0, CrossUp);
   SetIndexStyle(1, DRAW_ARROW, EMPTY);
   SetIndexArrow(1, 234);
   SetIndexBuffer(1, CrossDown);
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//---- 

//----
   return(0);
  }


//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start() {
   int limit, i, counter;
   double tmp=0;
   double fastMAnow, slowMAnow, fastMAprevious, slowMAprevious;
   double Range, AvgRange;
   int counted_bars=IndicatorCounted();
//---- check for possible errors
   if(counted_bars<0) return(-1);
//---- last counted bar will be recounted
   if(counted_bars>0) counted_bars--;

   limit=Bars-counted_bars;
   
   for(i = 1; i <= limit; i++) {
   
      counter=i;
      Range=0;
      AvgRange=0;
      for (counter=i ;counter<=i+9;counter++)
      {
         AvgRange=AvgRange+MathAbs(High[counter]-Low[counter]);
      }
      Range=AvgRange/10;
       
      fastMAnow = iStochastic(NULL, 0, KPeriod, DPeriod, Slowing,MA_Method, PriceField, MODE_MAIN, i);
      fastMAprevious = iStochastic(NULL, 0, KPeriod, DPeriod, Slowing,MA_Method, PriceField, MODE_MAIN, i+1);

      slowMAnow = iStochastic(NULL, 0, KPeriod, DPeriod, Slowing,MA_Method, PriceField, MODE_SIGNAL, i);
      slowMAprevious = iStochastic(NULL, 0, KPeriod, DPeriod, Slowing,MA_Method, PriceField, MODE_SIGNAL, i+1);
      
      CrossUp[i] = 0;
      CrossDown[i] = 0;
      if ((fastMAnow > slowMAnow) && (fastMAprevious < slowMAprevious))
      {
         if (i == 1 && flagval1==0)
         {
           flagval1=1;
           flagval2=0;
           if (SoundON) Alert("BUY signal at Ask=",Ask,"\n Bid=",Bid,"\n Time=",TimeToStr(CurTime(),TIME_DATE)," ",TimeHour(CurTime()),":",TimeMinute(CurTime()),"\n Symbol=",Symbol()," Period=",Period());
           if (EmailON) SendMail("BUY signal alert","BUY signal at Ask="+DoubleToStr(Ask,4)+", Bid="+DoubleToStr(Bid,4)+", Date="+TimeToStr(CurTime(),TIME_DATE)+" "+TimeHour(CurTime())+":"+TimeMinute(CurTime())+" Symbol="+Symbol()+" Period="+Period());
         }
         CrossUp[i] = Low[i] - Range*0.75;
      }
      else if ((fastMAnow < slowMAnow) && (fastMAprevious > slowMAprevious))
      {
         if (i == 1 && flagval2==0)
         {
          flagval2=1;
          flagval1=0;
         if (SoundON) Alert("SELL signal at Ask=",Ask,"\n Bid=",Bid,"\n Date=",TimeToStr(CurTime(),TIME_DATE)," ",TimeHour(CurTime()),":",TimeMinute(CurTime()),"\n Symbol=",Symbol()," Period=",Period());
         if (EmailON) SendMail("SELL signal alert","SELL signal at Ask="+DoubleToStr(Ask,4)+", Bid="+DoubleToStr(Bid,4)+", Date="+TimeToStr(CurTime(),TIME_DATE)+" "+TimeHour(CurTime())+":"+TimeMinute(CurTime())+" Symbol="+Symbol()+" Period="+Period());
         }
         CrossDown[i] = High[i] + Range*0.75;
      }
   }

   return(0);
}

Similar scripts

Stochastic_Cross_Alert_001

This indicator detects bullish and bearish trend shifts by identifying crossover points between the main and signal stochastic lines while providing real-time auditory, visual, and electronic notifications.

AIME_5820_Crossover_AlertNoMAs

This indicator identifies bullish and bearish momentum by detecting the intersection of a 5-period EMA (Price Close) and an 8-period EMA (Price Open), featuring automated visual markers and multi-channel notifications.

AIME_5820_Crossover_Alert

This indicator identifies bullish and bearish entries by detecting dynamic crossovers between a 5-period EMA on closing prices and an 8-period EMA on opening prices, supplemented by a trend-filtering 20-period EMA.

Stochastic_Cross_Alert_v1

This indicator identifies bullish and bearish market shifts by detecting precise crossovers between the fast and slow stochastic components while calculating dynamic volatility-based arrow positioning.

MA_PriceCrossover_Email_Alert

This indicator identifies trend reversals by detecting price breaches of dual moving average envelopes, supporting SMA, EMA, SMMA, LWMA, and LSMA calculations across various price types.

MA_Crossover_Email_Alert

This indicator detects trend reversals by monitoring momentum shifts between two customizable moving averages, triggering visual markers and automated notifications upon bullish or bearish crossovers.

MA_Crossover_Email_Alert_v1

This indicator identifies bullish and bearish trend shifts by detecting intersections between two customizable moving averages—including SMA, EMA, SMMA, LWMA, and LSMA—while providing real-time audio and email notifications.

#Stochastic_Cross_Alert_SigOverlayM_cw_001

This indicator identifies directional shifts by detecting K and D line intersections coupled with threshold breaches in overbought and oversold zones.

#Stochastic_Cross_Alert_SigOverlayM_cw

This indicator identifies potential reversal points by detecting specific momentum shifts when the stochastic oscillator crosses defined overbought/oversold thresholds or intersects its signal line.

Stochastic_Cross_Alert_SigOverlayM_sw

This indicator identifies trend reversals and momentum shifts by detecting specific breaches of overbought/oversold thresholds and main-signal line intersections with integrated multi-channel alerts.

cStochastic_Cross_Alert_SigOverlayM_cw

Comments