VWAP_Oscillator

ÿþ//+------------------------------------------------------------------+

//|                                              VWAP_Oscillator.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "Advance Volume Weighted Average Price oscillator"

#property indicator_separate_window

#property indicator_buffers 8

#property indicator_plots   3

//--- plot Daily

#property indicator_label1  "Daily VWAP osc"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDeepSkyBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot Weekly

#property indicator_label2  "Weekly VWAP osc"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot Daily/Weekly Osc

#property indicator_label3  "Daily/Weekly Osc"

#property indicator_type3   DRAW_COLOR_HISTOGRAM

#property indicator_color3  clrGreen,clrRed,clrDimGray

#property indicator_style3  STYLE_SOLID

#property indicator_width3  8

//--- enums

enum ENUM_INPUT_SHOW

  {

   SHOW_OSC,         // Daily/Weekly Oscillator

   SHOW_DW,          // Daily and Weekly lines

   SHOW_DAY,         // Daily line

   SHOW_WEEK         // Weekly line

  };

//---

enum ENUM_INPUT_YES_NO

  {

   INPUT_YES   =  1, // Yes

   INPUT_NO    =  0  // No

  };

//--- input parameters

input ENUM_INPUT_SHOW   InpShowMode =  SHOW_OSC;   // Draw mode

input ENUM_INPUT_YES_NO InpInverse  =  INPUT_NO;   // Inverse Daily/Weekly Osc 

//--- indicator buffers

double         BufferDaily[];

double         BufferWeekly[];

double         BufferOSC[];

double         BufferColors[];

double         BufferDailyRAW[];

double         BufferWeeklyRAW[];

double         BufferMonthlyRAW[];

double         BufferWP[];

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferDaily,INDICATOR_DATA);

   SetIndexBuffer(1,BufferWeekly,INDICATOR_DATA);

   SetIndexBuffer(2,BufferOSC,INDICATOR_DATA);

   SetIndexBuffer(3,BufferColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(4,BufferDailyRAW,INDICATOR_DATA);

   SetIndexBuffer(5,BufferWeeklyRAW,INDICATOR_DATA);

   SetIndexBuffer(6,BufferMonthlyRAW,INDICATOR_DATA);

   SetIndexBuffer(7,BufferWP,INDICATOR_CALCULATIONS);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"VWAP Osc");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferDaily,true);

   ArraySetAsSeries(BufferWeekly,true);

   ArraySetAsSeries(BufferOSC,true);

   ArraySetAsSeries(BufferColors,true);

   ArraySetAsSeries(BufferDailyRAW,true);

   ArraySetAsSeries(BufferWeeklyRAW,true);

   ArraySetAsSeries(BufferMonthlyRAW,true);

   ArraySetAsSeries(BufferWP,true);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- #AB0=>2:0 <0AA82>2 1CD5@>2 :0: B09<A5@89

   ArraySetAsSeries(high,true);

   ArraySetAsSeries(low,true);

   ArraySetAsSeries(close,true);

   ArraySetAsSeries(time,true);

   ArraySetAsSeries(tick_volume,true);

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<4) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-2;

      ArrayInitialize(BufferDaily,EMPTY_VALUE);

      ArrayInitialize(BufferWeekly,EMPTY_VALUE);

      ArrayInitialize(BufferOSC,EMPTY_VALUE);

      ArrayInitialize(BufferColors,2);

      ArrayInitialize(BufferDailyRAW,0);

      ArrayInitialize(BufferWeeklyRAW,0);

      ArrayInitialize(BufferMonthlyRAW,0);

      ArrayInitialize(BufferWP,0);

     }



//--- >43>B>2:0 40==KE

   for(int i=limit; i>=0 && !IsStopped(); i--)

      BufferWP[i]=tick_volume[i]*(high[i]+low[i]+close[i])/3.0;

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      BufferDailyRAW[i]=CalculateDaily(rates_total,i,time,tick_volume);

      BufferWeeklyRAW[i]=CalculateWeekly(rates_total,i,time,tick_volume);

      BufferMonthlyRAW[i]=CalculateMonthly(rates_total,i,time,tick_volume);

     }

   

//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      double D=BufferDailyRAW[i]-BufferMonthlyRAW[i];

      double W=BufferWeeklyRAW[i]-BufferMonthlyRAW[i];

      double O=D-W;

      BufferDaily[i]=(InpShowMode==SHOW_DAY || InpShowMode==SHOW_DW ? D : EMPTY_VALUE);

      BufferWeekly[i]=(InpShowMode==SHOW_WEEK || InpShowMode==SHOW_DW ? W : EMPTY_VALUE);

      if(InpShowMode==SHOW_OSC)

        {

         BufferDaily[i]=BufferWeekly[i]=EMPTY_VALUE;

         BufferOSC[i]=(InpInverse ? -O : O);

         BufferColors[i]=(BufferOSC[i]>BufferOSC[i+1] ? 0 : BufferOSC[i]<BufferOSC[i+1] ? 1 : 2);

        }

     }

   

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

double CalculateDaily(const int rates_total,const int shift,const datetime &time[],const long &volume[])

  {

   int index=shift;

   double sum1=0;

   double sum2=0;

   int DT=TimeDay(time[shift]);

   while(index<rates_total-1 && TimeDay(time[index])==DT)

     {

      sum1+=BufferWP[index];

      sum2+=(double)volume[index];

      index++;

     }

   return(sum2!=0 ? sum1/sum2 : EMPTY_VALUE);

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

double CalculateWeekly(const int rates_total,const int shift,const datetime &time[],const long &volume[])

  {

   int index=shift+1;

   double sum1=BufferWP[shift];

   double sum2=(double)volume[shift];

   while(index<rates_total-2 && TimeDayOfWeek(time[index+1])<=TimeDayOfWeek(time[index]))

     {

      sum1+=BufferWP[index];

      sum2+=(double)volume[index];

      index++;

     }

   return(sum2!=0 ? sum1/sum2 : EMPTY_VALUE);

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

double CalculateMonthly(const int rates_total,const int shift,const datetime &time[],const long &volume[])

  {

   int index=shift;

   double sum1=0;

   double sum2=0;

   int DT=TimeMonth(time[shift]);

   while(index<rates_total-1 && TimeMonth(time[index])==DT)

     {

      sum1+=BufferWP[index];

      sum2+=(double)volume[index];

      index++;

     }

   return(sum2!=0 ? sum1/sum2 : EMPTY_VALUE);

  }

//+------------------------------------------------------------------+

//| >72@0I05B 45=L <5AOF0 C:070==>9 40BK                            |

//+------------------------------------------------------------------+

int TimeDay(const datetime time)

  {

   MqlDateTime tm;

   if(!TimeToStruct(time,tm)) return WRONG_VALUE;

   return tm.day;

  }

//+------------------------------------------------------------------+

//| >72@0I05B 45=L =545;8 C:070==>9 40BK                            |

//+------------------------------------------------------------------+

int TimeDayOfWeek(const datetime time)

  {

   MqlDateTime tm;

   if(!TimeToStruct(time,tm)) return WRONG_VALUE;

   return tm.day_of_week;

  }

//+------------------------------------------------------------------+

//| >72@0I05B =><5@ <5AOF0 C:070==>3> 2@5<5=8                       |

//+------------------------------------------------------------------+

int TimeMonth(const datetime time)

  {

   MqlDateTime tm;

   if(!TimeToStruct(time,tm)) return WRONG_VALUE;

   return tm.mon;

  }

//+------------------------------------------------------------------+