ZigZag_NK_Color_v2

//+------------------------------------------------------------------+
//|                                              ZigZag_NK_Color.mq5 |
//|                      Copyright © 2005, MetaQuotes Software Corp. |
//|                                       http://www.metaquotes.net/ |
//+------------------------------------------------------------------+ 
/*                                                                   |
//Version: Final, November 01, 2008                                  |
Editing:   Nikolay Kositsin  farria@mail.redcom.ru                   |
//----- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -+ 
Ýòîò âàðèàíò èíäèêàòîðà ZigZag, â îòëè÷èå îò îðèãèíàëà, íà êàæäîì òèêå 
ïåðåñ÷èòûâàåòñÿ  òîëüêî íà  åù¸  íåïîñ÷èòàííûõ áàðàõ è ïîýòîìó  ñîâñåì 
íå ãðóçèò êîìïüþòåð.  Ïîìèìî ýòîãî â äàííîì èíäèêàòîðå îòðèñîâêà ëèíèè
ïðîèñõîäèò èìåííî â ñòèëå ZIGZAG,    è  ïîýòîìó  èíäèêàòîð   êîððåêòíî 
èçîáðàæàåò îäíîâðåìåííî äâå ñâîèõ âåðùèíû(Õàé è Ëîó) íà îäíîì è òîì æå 
áàðå!
Íèêîëàé Êîñèöèí
//----- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -+
Depth - ýòî  ìèíèìàëüíîå êîë-âî  áàðîâ, íà êîòîðîì  íå  áóäåò  âòîðîãî 
ìàêñèìóìà  (ìèíèìóìà)  ìåíüøå  (áîëüøå)  íà  Deviation  ïèïñîâ,    ÷åì 
ïðåäûäóùåãî, òî  åñòü  ðàñõîäèòüñÿ  ZigZag  ìîæåò  âñåãäà,  à ñõîäèòñÿ 
(ëèáî ñäâèíóòüñÿ  öåëèêîì) áîëüøå,  ÷åì  íà  Deviation,  ZigZag  ìîæåò 
òîëüêî ïîñëå Depth  áàðîâ. Backstep - ýòî ìèíèìàëüíîå êîëè÷åñòâî áàðîâ 
ìåæäó ìàêñèìóìàìè (ìèíèìóìàìè).
//----- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -+
Èíäèêàòîð  Çèãçàã  —  ðÿä ëèíèé òðåíäà, êîòîðûå ñîåäèíÿþò ñóùåñòâåííûå
âåðøèíû   è   îñíîâàíèÿ  íà  öåíîâîì  ãðàôèêå.  Ïàðàìåòð  ìèíèìàëüíîãî
èçìåíåíèÿ  öåí îïðåäåëÿåò ïðîöåíò, íà êîòîðûé öåíà äîëæíà ïåðåìåñòèòü,
÷òîáû  ñôîðìèðîâàòü  íîâóþ  "Çèã"  èëè  "Çàã"  ëèíèþ.  Ýòîò  èíäèêàòîð
îòñåèâàåò  èçìåíåíèÿ íà àíàëèçèðóåìîì ãðàôèêå, âåëè÷èíà êîòîðûõ ìåíüøå
çàäàííîé.   Òàêèì   îáðàçîì,   çèãçàã   îòðàæàåò  òîëüêî  ñóùåñòâåííûå
èçìåíåíèÿ.  Çèãçàã  èñïîëüçóåòñÿ,  ãëàâíûì  îáðàçîì,  äëÿ îáëåã÷åííîãî
âîñïðèÿòèÿ  ãðàôèêîâ,  òàê  êàê îí ïîêàçûâàåò òîëüêî íàèáîëåå çíà÷èìûå
èçìåíåíèÿ  è  ðàçâîðîòû.  Òàêæå  ñ  åãî  ïîìîùüþ  ìîæíî âûÿâëÿòü Âîëíû
Ýëëèîòà  è  ðàçëè÷íûå  ôèãóðû íà ãðàôèêå. Âàæíî óñâîèòü, ÷òî ïîñëåäíèé
îòðåçîê   èíäèêàòîðà   ìîæåò   ìåíÿòüñÿ  â  çàâèñèìîñòè  îò  èçìåíåíèé
àíàëèçèðóåìûõ  äàííûõ.  Ýòî  îäèí  èç íåìíîãèõ èíäèêàòîðîâ, ó êîòîðîãî
èçìåíåíèå  öåíû  áóìàãè  ìîæåò âûçâàòü èçìåíåíèå ïðåäûäóùåãî çíà÷åíèÿ.
Ïîäîáíàÿ  ñïîñîáíîñòü  êîððåêòèðîâêè  ñâîèõ  çíà÷åíèé  ïî  ïîñëåäóþùèì
èçìåíåíèÿì  öåíû äåëàåò Çèãçàã ïðåêðàñíûì èíñòðóìåíòîì äëÿ àíàëèçà óæå
ïðîèçîøåäøèõ  öåíîâûõ  èçìåíåíèé.  Ïîýòîìó íå ñëåäóåò ïûòàòüñÿ ñîçäàòü
òîðãîâóþ  ñèñòåìó  íà  îñíîâå  Çèãçàãà:  îí ëó÷øå ïîäõîäèò äëÿ àíàëèçà
èñòîðè÷åñêèõ äàííûõ, ÷åì äëÿ ïðîãíîçèðîâàíèÿ.
 */
//+------------------------------------------------------------------+ 
//---- àâòîðñòâî èíäèêàòîðà
#property copyright "Copyright © 2005, MetaQuotes Software Corp."
//---- ññûëêà íà ñàéò àâòîðà
#property link      "http://www.metaquotes.net/"
//---- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.00"
#property description "ZigZag" 
//---- îòðèñîâêà èíäèêàòîðà â ãëàâíîì îêíå
#property indicator_chart_window 
//---- äëÿ ðàñ÷¸òà è îòðèñîâêè èíäèêàòîðà èñïîëüçîâàíî 2 áóôåðà
#property indicator_buffers 3
//---- èñïîëüçîâàíî âñåãî 2 ãðàôè÷åñêèõ ïîñòðîåíèÿ
#property indicator_plots   1
//+----------------------------------------------+ 
//|  Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà              |
//+----------------------------------------------+
//---- â êà÷åñòâå èíäèêàòîðà èñïîëüçîâàí ZIGZAG
#property indicator_type1   DRAW_COLOR_ZIGZAG
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label1  "ZigZag"
//---- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàí ñèíå-ôèîëåòîâûé öâåò
#property indicator_color1 clrMagenta,clrBlueViolet
//---- ëèíèÿ èíäèêàòîðà - äëèííûé ïóíêòèð
#property indicator_style1  STYLE_DASH
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 1
#property indicator_width1  1
//+----------------------------------------------+ 
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+ 
input int ExtDepth=12;
input int ExtDeviation=5;
input int ExtBackstep=3;
//+----------------------------------------------+
//---- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå áóäóò â 
// äàëüíåéøåì èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double LowestBuffer[];
double HighestBuffer[];
double ColorBuffer[];

//---- Îáúÿâëåíèå ïåðåìåííûõ ïàìÿòè äëÿ ïåðåñ÷¸òà èíäèêàòîðà òîëüêî íà íåïîñ÷èòàííûõ áàðàõ
int LASTlowpos,LASThighpos,LASTColor;
double LASTlow0,LASTlow1,LASThigh0,LASThigh1;

//---- Îáúÿâëåíèå öåëûõ ïåðåìåííûõ íà÷àëà îòñ÷¸òà äàííûõ
int min_rates_total;
//+------------------------------------------------------------------+ 
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+ 
void OnInit()
  {
//---- Èíèöèàëèçàöèÿ ïåðåìåííûõ íà÷àëà îòñ÷¸òà äàííûõ
   min_rates_total=ExtDepth+ExtBackstep;

//---- ïðåâðàùåíèå äèíàìè÷åñêèõ ìàññèâîâ â èíäèêàòîðíûå áóôåðû
   SetIndexBuffer(0,LowestBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,HighestBuffer,INDICATOR_DATA);
   SetIndexBuffer(2,ColorBuffer,INDICATOR_COLOR_INDEX);
//---- çàïðåò íà îòðèñîâêó èíäèêàòîðîì ïóñòûõ çíà÷åíèé
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);
//---- ñîçäàíèå ìåòîê äëÿ îòîáðàæåíèÿ â Îêíå äàííûõ
   PlotIndexSetString(0,PLOT_LABEL,"ZigZag Lowest");
   PlotIndexSetString(1,PLOT_LABEL,"ZigZag Highest");
//---- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðàõ êàê â òàéìñåðèÿõ   
   ArraySetAsSeries(LowestBuffer,true);
   ArraySetAsSeries(HighestBuffer,true);
   ArraySetAsSeries(ColorBuffer,true);
//---- óñòàíîâêà ïîçèöèè, ñ êîòîðîé íà÷èíàåòñÿ îòðèñîâêà óðîâíåé Áîëëèíäæåðà
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
//---- Óñòàíîâêà ôîðìàòà òî÷íîñòè îòîáðàæåíèÿ èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//---- èìÿ äëÿ îêîí äàííûõ è ëýéáà äëÿ ñóáúîêîí 
   string shortname;
   StringConcatenate(shortname,"ZigZag (ExtDepth=",
                     ExtDepth,"ExtDeviation = ",ExtDeviation,"ExtBackstep = ",ExtBackstep,")");
   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
//----   
  }
//+------------------------------------------------------------------+ 
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+ 
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷¸òà
   if(rates_total<min_rates_total) return(0);

//---- îáúÿâëåíèÿ ëîêàëüíûõ ïåðåìåííûõ 
   int limit,climit,bar,back,lasthighpos,lastlowpos;
   double curlow,curhigh,lasthigh0,lastlow0,lasthigh1,lastlow1,val,res;
   bool Max,Min;

//---- ðàñ÷¸ò ñòàðòîâîãî íîìåðà limit äëÿ öèêëà ïåðåñ÷¸òà áàðîâ è ñòàðòîâàÿ èíèöèàëèçàöèÿ ïåðåìåííûõ
   if(prev_calculated>rates_total || prev_calculated<=0)// ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷¸òà èíäèêàòîðà
     {
      limit=rates_total-min_rates_total; // ñòàðòîâûé íîìåð äëÿ ðàñ÷¸òà âñåõ áàðîâ
      climit=limit; // ñòàðòîâûé íîìåð äëÿ ðàñêðàñêè èíäèêàòîðà

      lastlow1=-1;
      lasthigh1=-1;
      lastlowpos=-1;
      lasthighpos=-1;
     }
   else
     {
      limit=rates_total-prev_calculated; // ñòàðòîâûé íîìåð äëÿ ðàñ÷¸òà íîâûõ áàðîâ
      climit=limit+min_rates_total; // ñòàðòîâûé íîìåð äëÿ ðàñêðàñêè èíäèêàòîðà

      //---- âîññòàíàâëèâàåì çíà÷åíèÿ ïåðåìåííûõ
      lastlow0=LASTlow0;
      lasthigh0=LASThigh0;

      lastlow1=LASTlow1;
      lasthigh1=LASThigh1;

      lastlowpos=LASTlowpos+limit;
      lasthighpos=LASThighpos+limit;
     }

//---- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ êàê â òàéìñåðèÿõ  
   ArraySetAsSeries(high,true);
   ArraySetAsSeries(low,true);

//---- Ïåðâûé áîëüøîé öèêë ðàñ÷¸òà èíäèêàòîðà
   for(bar=limit; bar>=0 && !IsStopped(); bar--)
     {
      //---- çàïîìèíàåì çíà÷åíèÿ ïåðåìåííûõ ïåðåä ïðîãîíàìè íà òåêóùåì áàðå
      if(rates_total!=prev_calculated && bar==0)
        {
         LASTlow0=lastlow0;
         LASThigh0=lasthigh0;
        }

      //--- low
      val=low[ArrayMinimum(low,bar,ExtDepth)];
      if(val==lastlow0) val=0.0;
      else
        {
         lastlow0=val;
         if(low[bar]-val>ExtDeviation*_Point)val=0.0;
         else
           {
            for(back=1; back<=ExtBackstep; back++)
              {
               res=LowestBuffer[bar+back];
               if((res!=0) && (res>val))
                 {
                  LowestBuffer[bar+back]=0.0;
                 }
              }
           }
        }
      LowestBuffer[bar]=val;

      //--- high
      val=high[ArrayMaximum(high,bar,ExtDepth)];
      if(val==lasthigh0) val=0.0;
      else
        {
         lasthigh0=val;
         if(val-high[bar]>ExtDeviation*_Point)val=0.0;
         else
           {
            for(back=1; back<=ExtBackstep; back++)
              {
               res=HighestBuffer[bar+back];
               if((res!=0) && (res<val))
                 {
                  HighestBuffer[bar+back]=0.0;
                 }
              }
           }
        }
      HighestBuffer[bar]=val;
     }

//---- Âòîðîé áîëüøîé öèêë ðàñ÷¸òà èíäèêàòîðà
   for(bar=limit; bar>=0 && !IsStopped(); bar--)
     {
      //---- çàïîìèíàåì çíà÷åíèÿ ïåðåìåííûõ ïåðåä ïðîãîíàìè íà òåêóùåì áàðå
      if(rates_total!=prev_calculated && bar==0)
        {
         LASTlow1=lastlow1;
         LASThigh1=lasthigh1;
         //----
         LASTlowpos=lastlowpos;
         LASThighpos=lasthighpos;
        }

      curlow=LowestBuffer[bar];
      curhigh=HighestBuffer[bar];
      //---
      if(!curlow&& !curhigh)continue;
      //---
      if(curhigh!=0)
        {
         if(lasthigh1>0)
           {
            if(lasthigh1<curhigh)
              {
               HighestBuffer[lasthighpos]=0;
              }
            else
              {
               HighestBuffer[bar]=0;
              }
           }
         //---
         if(lasthigh1<curhigh || lasthigh1<0)
           {
            lasthigh1=curhigh;
            lasthighpos=bar;
           }
         lastlow1=-1;
        }
      //----
      if(curlow!=0)
        {
         if(lastlow1>0)
           {
            if(lastlow1>curlow)
              {
               LowestBuffer[lastlowpos]=0;
              }
            else
              {
               LowestBuffer[bar]=0;
              }
           }
         //---
         if(curlow<lastlow1 || lastlow1<0)
           {
            lastlow1=curlow;
            lastlowpos=bar;
           }
         lasthigh1=-1;
        }
     }

//---- Òðåòèé áîëüøîé öèêë ðàñêðàñêè èíäèêàòîðà
   for(bar=climit; bar>=0 && !IsStopped(); bar--)
     {
      Max=HighestBuffer[bar];
      Min=LowestBuffer[bar];
      
      if(!Max && !Min) ColorBuffer[bar]=ColorBuffer[bar+1];
      if( Max &&  Min)
        {
         if(ColorBuffer[bar+1]==0) ColorBuffer[bar]=1;
         else                      ColorBuffer[bar]=0;
        }

      if( Max && !Min) ColorBuffer[bar]=1;
      if(!Max &&  Min) ColorBuffer[bar]=0;
     }
//----     
   return(rates_total);
  }
//+------------------------------------------------------------------+