Brooky_Rsi_Ichimoku_V2
Download scriptThis script is a specialized financial analysis tool designed for the MetaTrader platform. It combines two popular trading methodologies—the Ichimoku Kinko Hyo and the Relative Strength Index (RSI)—into a single unified indicator.
Instead of applying the Ichimoku system directly to price action, this script performs a unique calculation by applying the entire Ichimoku logic to the RSI values. This allows traders to visualize momentum trends and potential reversals through a "cloud" and "line" system based on strength oscillators rather than raw price movements.
Core Logic and Components
The tool generates several distinct visual elements to help identify market structure:
1. The Momentum Lines (Tenkan-sen and Kijun-sen) The script calculates two primary lines that represent short-term and medium-term momentum.
- The Tenkan-sen acts as a fast-moving average, determining the immediate direction of the RSI.
- The Kijun-sen acts as a slower moving average, providing a broader view of the trend. By comparing these two lines, traders can look for "crosses" to identify shifts in momentum strength.
2. The Momentum Cloud (Senkou Spans) This is the most visually prominent feature of the tool. It creates a shaded area (the cloud) based on two different components:
- Senkou Span A: Calculated as the average of the two momentum lines mentioned above.
- Senkou Span B: Calculated using a much longer look-back period to identify long-term equilibrium. The space between these two spans forms a "cloud." When the cloud is thick or moving in a specific direction, it suggests the prevailing trend of the RSI; when the clouds cross or change color, it may signal a potential exhaustion of that momentum.
3. The Lagging Momentum (Chinkou Span) The script includes a lagging line that displays the current RSI value shifted backward on the chart. This serves as a visual confirmation tool to see how current strength compares to where it was in the past, helping to filter out "false" signals.
Key Technical Features
- Dynamic Background Integration: The script includes a unique feature that detects the color of your chart's background and automatically adjusts its own internal filling colors. This ensures that the "cloud" remains visible and professional-looking regardless of whether you are using a dark or light theme.
- High/Low Sensitivity: Rather than simply looking at where prices close, the script identifies the highest highs and lowest lows within specific time windows to calculate its averages. This makes the indicator more resilient to sudden price spikes that might otherwise skew the data.
- Customizable Periods: Users can adjust the look-back periods for both the RSI and the various Ichimoku components to suit different trading styles (e.g., faster for day trading or slower for long-term swing trading).
Summary of Usage
In simple terms, this tool tells you: "Based on how fast and strong the market momentum is moving (RSI), what does the overall trend look like?" It translates complex price volatility into a structured visual map of "Clouds" and "Lines," making it easier to spot where momentum is accelerating or slowing down.
//+------------------------------------------------------------------+
//| Brooky_Rsi_Ichimoku_V2.mq4 |
//| Copyright © 2004, MetaQuotes Software Corp. |
//| http://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2004, MetaQuotes Software Corp."
#property link "http://www.metaquotes.net/"
#property indicator_separate_window
#property indicator_buffers 8
#property indicator_color1 Blue
#property indicator_color2 Red
#property indicator_color3 C'241,139,56'
#property indicator_color4 Thistle
#property indicator_color5 Lime
#property indicator_color6 C'241,139,56'
#property indicator_color7 Thistle
#property indicator_color8 C'82,82,82'
#property indicator_width1 3
#property indicator_width2 3
#property indicator_width5 3
#property indicator_level1 50
#property indicator_level2 30
#property indicator_level3 70
//--auto color
#import "user32.dll"
int GetDC(int hwnd);
int ReleaseDC(int hwnd,int hdc);
#import "gdi32.dll"
color GetPixel(int hdc,int x,int y);
//---- input parameters
extern string Author_Site = "www.Brooky-Indicators.com";
extern string NOTE = "+--DLL Must Be Allowed--+";
extern string NOTE2 = "+--For Auto Clear Backgound--+";
extern int Tenkan=9;
extern int Kijun=26;
extern int Senkou=52;
extern string RSI_Period =" Set RSI Period Below";
extern int Rsip =14;
extern string Cloud_Style ="2 for Dots : 0 for Line";
extern int CL_Style =0;
//---- buffers
double Tenkan_Buffer[];
double Kijun_Buffer[];
double SpanA_Buffer[];
double SpanB_Buffer[];
double Chinkou_Buffer[];
double SpanA2_Buffer[];
double SpanB2_Buffer[];
double Fill_Buffer[];
//----
int a_begin;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int init()
{
//----
IndicatorShortName("Brooky-Indicators.com RSI Ichimoku ("+Rsip);
SetIndexStyle(0,DRAW_LINE);
SetIndexBuffer(0,Tenkan_Buffer);
SetIndexDrawBegin(0,Tenkan-1);
SetIndexLabel(0,"Tenkan Sen");
//----
SetIndexStyle(1,DRAW_LINE);
SetIndexBuffer(1,Kijun_Buffer);
SetIndexDrawBegin(1,Kijun-1);
SetIndexLabel(1,"Kijun Sen");
//----
a_begin=Kijun; if(a_begin<Tenkan) a_begin=Tenkan;
SetIndexStyle(2,DRAW_HISTOGRAM,CL_Style);
SetIndexBuffer(2,SpanA_Buffer);
SetIndexDrawBegin(2,Kijun+a_begin-1);
SetIndexShift(2,Kijun);
SetIndexLabel(2,NULL);
SetIndexStyle(5,DRAW_LINE,CL_Style);
SetIndexBuffer(5,SpanA2_Buffer);
SetIndexDrawBegin(5,Kijun+a_begin-1);
SetIndexShift(5,Kijun);
SetIndexLabel(5,"Senkou Span A");
//----
SetIndexStyle(3,DRAW_HISTOGRAM,CL_Style);
SetIndexBuffer(3,SpanB_Buffer);
SetIndexDrawBegin(3,Kijun+Senkou-1);
SetIndexShift(3,Kijun);
SetIndexLabel(3,NULL);
SetIndexStyle(6,DRAW_LINE,CL_Style);
SetIndexBuffer(6,SpanB2_Buffer);
SetIndexDrawBegin(6,Kijun+Senkou-1);
SetIndexShift(6,Kijun);
SetIndexLabel(6,"Senkou Span B");
//----
SetIndexStyle(4,DRAW_LINE);
SetIndexBuffer(4,Chinkou_Buffer);
SetIndexShift(4,-Kijun);
SetIndexLabel(4,"Chinkou Span");
//SetIndexStyle(7,DRAW_HISTOGRAM);
SetIndexBuffer(7,Fill_Buffer);
SetIndexDrawBegin(7,Kijun+Senkou-1);
SetIndexShift(7,Kijun);
//----
return(0);
}
//+------------------------------------------------------------------+
//| Ichimoku Kinko Hyo on RSI |
//+------------------------------------------------------------------+
int start()
{
int hwnd=WindowHandle(Symbol(),Period());
int hdc=GetDC(hwnd);
color back_ground=GetPixel(hdc,1,2);
ReleaseDC(hwnd,hdc);
SetIndexStyle(7,DRAW_HISTOGRAM,0,EMPTY,back_ground);
int i,k;
int counted_bars=IndicatorCounted();
double high,low,price;
//----
if(Bars<=Tenkan || Bars<=Kijun || Bars<=Senkou) return(0);
//---- initial zero
if(counted_bars<1)
{
for(i=1;i<=Tenkan;i++) Tenkan_Buffer[Bars-i]=0;
for(i=1;i<=Kijun;i++) Kijun_Buffer[Bars-i]=0;
for(i=1;i<=a_begin;i++) { SpanA_Buffer[Bars-i]=0; SpanA2_Buffer[Bars-i]=0; }
for(i=1;i<=Senkou;i++) { SpanB_Buffer[Bars-i]=0; SpanB2_Buffer[Bars-i]=0; }
}
//---- Tenkan Sen
i=Bars-Tenkan;
if(counted_bars>Tenkan) i=Bars-counted_bars-1;
while(i>=0)
{
high=iRSI(NULL,0,Rsip,PRICE_HIGH,i);
low=iRSI(NULL,0,Rsip,PRICE_LOW,i); k=i-1+Tenkan;
while(k>=i)
{
price=iRSI(NULL,0,Rsip,PRICE_HIGH,k);
if(high<price) high=price;
price=iRSI(NULL,0,Rsip,PRICE_LOW,k);
if(low>price) low=price;
k--;
}
Tenkan_Buffer[i]=(high+low)/2;
i--;
}
//---- Kijun Sen
i=Bars-Kijun;
if(counted_bars>Kijun) i=Bars-counted_bars-1;
while(i>=0)
{
high=iRSI(NULL,0,Rsip,PRICE_HIGH,i);
low=iRSI(NULL,0,Rsip,PRICE_LOW,i); k=i-1+Kijun;
while(k>=i)
{
price=iRSI(NULL,0,Rsip,PRICE_HIGH,k);
if(high<price) high=price;
price=iRSI(NULL,0,Rsip,PRICE_LOW,k);
if(low>price) low=price;
k--;
}
Kijun_Buffer[i]=(high+low)/2;
i--;
}
//---- Senkou Span A
i=Bars-a_begin+1;
if(counted_bars>a_begin-1) i=Bars-counted_bars-1;
while(i>=0)
{
price=(Kijun_Buffer[i]+Tenkan_Buffer[i])/2;
SpanA_Buffer[i]=price;
SpanA2_Buffer[i]=price;
i--;
}
//---- Senkou Span B
i=Bars-Senkou;
if(counted_bars>Senkou) i=Bars-counted_bars-1;
while(i>=0)
{
high=iRSI(NULL,0,Rsip,PRICE_HIGH,i);
low=iRSI(NULL,0,Rsip,PRICE_LOW,i);k=i-1+Senkou;
while(k>=i)
{
price=iRSI(NULL,0,Rsip,PRICE_HIGH,k);
if(high<price) high=price;
price=iRSI(NULL,0,Rsip,PRICE_LOW,k);
if(low>price) low=price;
k--;
}
price=(high+low)/2;
SpanB_Buffer[i]=price;
SpanB2_Buffer[i]=price;
if(SpanA_Buffer[i]<=SpanB_Buffer[i])
{
Fill_Buffer[i]=SpanA_Buffer[i];
}
if(SpanA_Buffer[i]>SpanB_Buffer[i])
{
Fill_Buffer[i]=SpanB_Buffer[i];
}
i--;
}
//---- Chinkou Span
i=Bars-1;
if(counted_bars>1) i=Bars-counted_bars-1;
while(i>=0) { Chinkou_Buffer[i]=iRSI(NULL,0,Rsip,PRICE_CLOSE,i); i--; }
//----
return(0);
}
//+------------------------------------------------------------------+
Comments