NRTR Gator

Author: Rosh
NRTR Gator

This script is designed to identify potential buying and selling opportunities in a financial market by analyzing price trends and volatility. It uses two main components: a Non-Repainting Trend Rider (NRTR) and the Alligator indicator.

Here's a breakdown of the script's logic:

  1. Initialization: The script starts by setting up some basic parameters. PerATR determines the period, in number of past price bars used to calculate average volatility. kATR is a multiplier for that volatility. useSendMail toggles alerts being sent to the user via email.

  2. Trend Determination (NRTR):

    • The script calculates potential support ("buy") and resistance ("sell") levels based on the PerATR and kATR parameters. This calculation uses current price of the instrument to create dynamically adjusted upper and lower boundaries for trend. These boundaries are the BuyBuffer and SellBuffer.
    • It analyzes the price movements of the financial instrument to identify whether the price is generally trending upwards or downwards. This overall trend is stored in the Trend array which is equal to 1.0 for an uptrend and -1.0 for a downtrend.
    • If the price breaks through a resistance level, it suggests a potential continuation of an upward trend. Conversely, if the price breaks through a support level, it suggests a potential continuation of a downward trend.
    • The script tracks whether new highs or lows are being made to confirm trend continuation.
    • If the trend breaks a key level or makes a new significant high/low, the script signals a potential reversal of the trend and adjusts support/resistance levels accordingly. It will switch the Trend variable's sign to signal the new direction.

  3. Alligator Indicator:

    • The Alligator indicator is a collection of three smoothed moving averages that represent the jaw, teeth, and lips of a metaphorical alligator. It's used to confirm the NRTR indicator, filter false signals and indicate when a trend is present.
    • The script compares the relative positions of these three lines (jaw, teeth, and lips) to determine whether the "alligator" is "sleeping" (lines are intertwined, indicating consolidation) or "awake" and "eating" (lines are separated and diverging, indicating a trend). The GatorTrend array is populated accordingly.

  4. Signal Generation:

    • The script combines the information from the NRTR and the Alligator indicator. If both indicators agree on the direction of the trend (e.g., both indicate an upward trend), the script may generate a buy signal. Conversely, if both indicators suggest a downward trend, it may generate a sell signal.
    • UpBar and DownBar are visual representations (histograms) of where the price is relative to the Gator indicator, providing further confirmation of the signals.

  5. Iteration: The script analyzes each price bar (a single unit of time on the chart) sequentially, recalculating the indicators and potentially updating buy/sell signals. The code loops from the oldest to the newest bars, ensuring the data is consistent.

In simple terms, this script is like a weather forecaster for the financial markets. It uses different tools (indicators) to analyze the current conditions and predict future price movements, helping traders to identify potential buying and selling opportunities. It is useful when the two indicators agree, or can be misleading if used alone. The Alligator Indicator is used here for confirmation, helping reduce incorrect signals.

Indicators Used
Indicator of the average true rangeBill Williams Alligator
Miscellaneous
Implements a curve of type %1
13 Views
0 Downloads
0 Favorites
NRTR Gator 
//+------------------------------------------------------------------+
//|                                                   NRTR_Gator.mq4 |
//|                                                             Rosh |
//|                           http://forexsystems.ru/phpBB/index.php |
//+------------------------------------------------------------------+
#property copyright "Rosh"
#property link      "http://forexsystems.ru/phpBB/index.php"

#property indicator_chart_window
#property indicator_buffers 6
#property indicator_color1 Tomato
#property indicator_color2 DeepSkyBlue
#property indicator_color3 DeepSkyBlue
#property indicator_color4 Tomato
#property indicator_color5 Green
#property indicator_color6 Red
//---- input parameters
extern int       PerATR=40;
extern double    kATR=2.0;
extern bool      useSendMail=false;
//---- buffers
double SellBuffer[];
double BuyBuffer[];
double Ceil[];
double Floor[];
double Trend[];
double UpBar[];
double DownBar[];
double GatorTrend[];
int sm_Bars, supervizerShift,SymbolSpread,GatorBars;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- indicators
   IndicatorBuffers(8);

   SetIndexStyle(0,DRAW_ARROW);
   SetIndexArrow(0,251);
   SetIndexBuffer(0,SellBuffer);
   SetIndexEmptyValue(0,0.0);
   SetIndexLabel(0,"Ëèíèÿ ïðîäàæè");

   SetIndexStyle(1,DRAW_ARROW);
   SetIndexArrow(1,251);
   SetIndexBuffer(1,BuyBuffer);
   SetIndexEmptyValue(1,0.0);
   SetIndexLabel(1,"Ëèíèÿ ïîêóïêè");

   SetIndexStyle(2,DRAW_ARROW);
   SetIndexArrow(2,159);
   SetIndexBuffer(2,Ceil);
   SetIndexEmptyValue(2,0.0);
   SetIndexLabel(2,"Ïîòîëîê");

   SetIndexStyle(3,DRAW_ARROW);
   SetIndexArrow(3,159);
   SetIndexBuffer(3,Floor);
   SetIndexEmptyValue(3,0.0);
   SetIndexLabel(3,"Ïîë");

   SetIndexStyle(4,DRAW_HISTOGRAM,EMPTY,2);
   SetIndexBuffer(4,UpBar);
   SetIndexEmptyValue(4,0.0);
   SetIndexLabel(4,"Âåðõ áàðà");

   SetIndexStyle(5,DRAW_HISTOGRAM,EMPTY,2);
   SetIndexBuffer(5,DownBar);
   SetIndexEmptyValue(5,0.0);
   SetIndexLabel(5,"Íèç áàðà");

   SetIndexBuffer(6,Trend);   
   SetIndexEmptyValue(6,0.0);
   SetIndexLabel(6,"NRTR òðåíä");
   
   SetIndexBuffer(7,GatorTrend);   
   SetIndexEmptyValue(7,0.0);
   SetIndexLabel(7,"Gator òðåíä");

   SymbolSpread=MarketInfo(Symbol(),MODE_SPREAD);

   //----
   return(0);
  }
//+------------------------------------------------------------------+
//| ïðîáèòèå âåðõà ÄÀÓÍòðåíäà                              |
//+------------------------------------------------------------------+
bool BreakDown(int shift)
  {
   bool result=false;
   if (Close[shift]>SellBuffer[shift+1]) result=true;
   return(result);
  }

//+------------------------------------------------------------------+
//| ïðîáèòèå äíà ÀÏòðåíäà                              |
//+------------------------------------------------------------------+
bool BreakUp(int shift)
  {
   bool result=false;
   if (Close[shift]<BuyBuffer[shift+1]) result=true;
   return(result);
  }

//+------------------------------------------------------------------+
//| âçÿòèå íîâîãî ìèíèìóìà ïî ÄÀÓÍòðåíäó                             |
//+------------------------------------------------------------------+
bool BreakFloor(int shift)
  {
   bool result=false;
   if (High[shift]<Floor[shift+1]) result=true;
   return(result);
  }

//+------------------------------------------------------------------+
//| âçÿòèå íîâîãî ìàêñèìóìà ïî ÀÏòðåíäó                              |
//+------------------------------------------------------------------+
bool BreakCeil(int shift)
  {
   bool result=false;
   if (Low[shift]>Ceil[shift+1]) result=true;
   return(result);
  }

//+------------------------------------------------------------------+
//| îïðåäåëåíèå ïðåäûäóùåãî òðåíäà                                   |
//+------------------------------------------------------------------+
bool Uptrend(int shift)
  {
   bool result=false;
   if (Trend[shift+1]==1.0) result=true;
   if (Trend[shift+1]==-1.0) result=false;
   if ((Trend[shift+1]!=1.0)&&(Trend[shift+1]!=-1)) Print("Âíèìàíèå! Òðåíä íå îïðåäåëåí, òàêîãî áûòü íå ìîæåò. Áàð îò êîíöà ",(Bars-shift));
   return(result);
  }

//+------------------------------------------------------------------+
//| âû÷èñëåíèå âîëàòèëüíîñòè                                         |
//+------------------------------------------------------------------+
double ATR(int iPer,int shift)
  {
   double result;
   result=iATR(NULL,0,iPer,shift);
   return(result);
  }
//+------------------------------------------------------------------+
//| óñòàíîâêà íîâîãî óðîâíÿ ïîòîëêà                                  |
//+------------------------------------------------------------------+
void NewCeil(int shift)
  {
   Ceil[shift]=Close[shift];
   Floor[shift]=0.0;
  }

//+------------------------------------------------------------------+
//| óñòàíîâêà íîâîãî óðîâíÿ ïîëà                                     |
//+------------------------------------------------------------------+
void NewFloor(int shift)
  {
   Floor[shift]=Close[shift];
   Ceil[shift]=0.0;
  }

//+------------------------------------------------------------------+
//| óñòàíîâêà óðîâíÿ ïîääåðæêè ÀÏòðåíäà                              |
//+------------------------------------------------------------------+
void SetBuyBuffer(int shift)
  {
   BuyBuffer[shift]=Close[shift]-kATR*ATR(PerATR,shift);
   SellBuffer[shift]=0.0;
  }

//+------------------------------------------------------------------+
//| óñòàíîâêà óðîâíÿ ïîääåðæêè ÄÀÓÍòðåíäà                            |
//+------------------------------------------------------------------+
void SetSellBuffer(int shift)
  {
   SellBuffer[shift]=Close[shift]+kATR*ATR(PerATR,shift);
   BuyBuffer[shift]=0.0;
  }

//+------------------------------------------------------------------+
//| ðåâåðñ òðåíäà è óñòàíîâêà íîâûõ óðîâíåé                          |
//+------------------------------------------------------------------+
void NewTrend(int shift)
  {
   if (Trend[shift+1]==1.0) 
      {
      Trend[shift]=-1.0;
      NewFloor(shift);
      SetSellBuffer(shift);
      }
   else 
      {
      Trend[shift]=1.0;
      NewCeil(shift);
      SetBuyBuffer(shift);
      }
   if ((Trend[shift+1]!=1)&&(Trend[shift+1]!=-1)) Print("Âíèìàíèå! Òðåíä íå îïðåäåëåí, òàêîãî áûòü íå ìîæåò");
  }

//+------------------------------------------------------------------+
//| ïðîäîëæåíèå òðåíäà                                               |
//+------------------------------------------------------------------+
void CopyLastValues(int shift)
  {
   SellBuffer[shift]=SellBuffer[shift+1];
   BuyBuffer[shift]=BuyBuffer[shift+1];
   Ceil[shift]=Ceil[shift+1];
   Floor[shift]=Floor[shift+1];
   Trend[shift]=Trend[shift+1];
  }

//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
  {
//---- 
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
  {
   int    counted_bars=IndicatorCounted();
   int limit;
   if (counted_bars>0) limit=Bars-counted_bars;
   if (counted_bars<0) return(0);
   if (counted_bars==0) 
      {
      limit=Bars-PerATR-1;
      if (Close[limit+1]>Open[limit+1]) {Trend[limit+1]=1.0;Ceil[limit+1]=Close[limit+1];BuyBuffer[limit+1]=Close[limit+1]-kATR*ATR(PerATR,limit+1);}
      if (Close[limit+1]<Open[limit+1]) {Trend[limit+1]=-1.0;Floor[limit+1]=Close[limit+1];SellBuffer[limit+1]=Close[limit+1]+kATR*ATR(PerATR,limit+1);}
      if (Close[limit+1]==Open[limit+1]) {Trend[limit+1]=1.0;Ceil[limit+1]=Close[limit+1];BuyBuffer[limit+1]=Close[limit+1]-kATR*ATR(PerATR,limit+1);}
      }
//----
   for (int cnt=limit;cnt>=0;cnt--)
      {
      supervizerShift=cnt;

      if ((iAlligator(NULL,0,13,8,8,5,5,3,MODE_SMMA,PRICE_MEDIAN,MODE_GATORJAW,cnt)<iAlligator(NULL,0,13,8,8,5,5,3,MODE_SMMA,PRICE_MEDIAN,MODE_GATORTEETH,cnt))&&
         (iAlligator(NULL,0,13,8,8,5,5,3,MODE_SMMA,PRICE_MEDIAN,MODE_GATORTEETH,cnt)<iAlligator(NULL,0,13,8,8,5,5,3,MODE_SMMA,PRICE_MEDIAN,MODE_GATORLIPS,cnt)))
         GatorTrend[cnt]=1.0;
      if ((iAlligator(NULL,0,13,8,8,5,5,3,MODE_SMMA,PRICE_MEDIAN,MODE_GATORJAW,cnt)>iAlligator(NULL,0,13,8,8,5,5,3,MODE_SMMA,PRICE_MEDIAN,MODE_GATORTEETH,cnt))&&
         (iAlligator(NULL,0,13,8,8,5,5,3,MODE_SMMA,PRICE_MEDIAN,MODE_GATORTEETH,cnt)>iAlligator(NULL,0,13,8,8,5,5,3,MODE_SMMA,PRICE_MEDIAN,MODE_GATORLIPS,cnt)))
         GatorTrend[cnt]=-1.0;

      if(GatorTrend[cnt]==1.0) {UpBar[cnt]=High[cnt];DownBar[cnt]=Low[cnt];}
      if(GatorTrend[cnt]==-1.0) {UpBar[cnt]=Low[cnt];DownBar[cnt]=High[cnt];}

      if (Uptrend(cnt))
         {
         if (BreakCeil(cnt))
            {
            NewCeil(cnt);
            SetBuyBuffer(cnt);
            Trend[cnt]=1.0;
            continue;
            }
         if (BreakUp(cnt))
            {
            NewTrend(cnt);
            continue;
            }   
         CopyLastValues(cnt);
         }
      else
         {
         if (BreakFloor(cnt))
            {
            NewFloor(cnt);
            SetSellBuffer(cnt);
            Trend[cnt]=-1.0;
            continue;
            }
         if (BreakDown(cnt))
            {
            NewTrend(cnt);
            continue;
            }   
         CopyLastValues(cnt);
         }
      } 

//----
   return(0);
  }
//+------------------------------------------------------------------+

Similar scripts

NRTR_Rosh_v2e_mtf[1]

NRTR Rosh v2_v2

NRTR Rosh

Ind-NRTR-1

Ind-NRTR

NRTR Rosh v2_v1

NRTR_Rosh_v2eAlert_mtf

SupertrendLX

VKW Bands

Supertrend_v1

NRTR WATR-hist

Comments